Avatar of ChrisPritchard

ChrisPritchard's solution

to Hangman in the F# Track

Published at Aug 26 2018 · 1 comment
Instructions
Test suite
Solution

Implement the logic of the hangman game using functional reactive programming.

Hangman is a simple word guessing game.

Functional Reactive Programming is a way to write interactive programs. It differs from the usual perspective in that instead of saying "when the button is pressed increment the counter", you write "the value of the counter is the sum of the number of times the button is pressed."

Implement the basic logic behind hangman using functional reactive programming. You'll need to install an FRP library for this, this will be described in the language/track specific files of the exercise.

Running the tests

To run the tests, run the command dotnet test from within the exercise directory.

Further information

For more detailed information about the F# track, including how to get help if you're having trouble, please visit the exercism.io F# language page.

Submitting Incomplete Solutions

It's possible to submit an incomplete solution so you can see how others have completed the exercise.

HangmanTest.fs

// This file was created manually and its version is 1.0.0.

module HangmanTest

open Xunit
open FsUnit.Xunit

open Hangman

[<Fact>]
let ``Initially 9 failures are allowed`` () =
    let game = createGame "foo"
    let states = statesObservable game

    let mutable lastProgress = Busy 9
    states.Add(fun state -> lastProgress <- state.progress) |> ignore

    startGame game |> ignore

    lastProgress |> should equal <| Busy 9

[<Fact(Skip = "Remove to run test")>]
let ``Initially no letters are guessed`` () =
    let game = createGame "foo"
    let states = statesObservable game

    let mutable lastMaskedWord = ""
    states.Add(fun state -> lastMaskedWord <- state.maskedWord) |> ignore

    startGame game |> ignore

    lastMaskedWord |> should equal "___"

[<Fact(Skip = "Remove to run test")>]
let ``After 10 failures the game is over`` () =
    let game = createGame "foo"
    let states = statesObservable game

    let mutable lastProgress = Busy 9
    states.Add(fun state -> lastProgress <- state.progress) |> ignore

    startGame game |> ignore

    [for x in 1..10 do makeGuess 'x' game] |> ignore

    lastProgress |> should equal Lose
    
[<Fact(Skip = "Remove to run test")>]
let ``Feeding a correct letter removes underscores`` () =
    let game = createGame "foobar"
    let states = statesObservable game

    let mutable lastState = None
    states.Add(fun state -> lastState <- Some state) |> ignore

    startGame game |> ignore

    makeGuess 'b' game |> ignore

    lastState.Value.progress |> should equal <| Busy 9
    lastState.Value.maskedWord |> should equal "___b__"

    makeGuess 'o' game |> ignore

    lastState.Value.progress |> should equal <| Busy 9
    lastState.Value.maskedWord |> should equal "_oob__"
    
[<Fact(Skip = "Remove to run test")>]
let ``Feeding a correct letter twice counts as a failure`` () =
    let game = createGame "foobar"
    let states = statesObservable game

    let mutable lastState = None
    states.Add(fun state -> lastState <- Some state) |> ignore

    startGame game |> ignore

    makeGuess 'b' game |> ignore

    lastState.Value.progress |> should equal <| Busy 9
    lastState.Value.maskedWord |> should equal "___b__"

    makeGuess 'b' game |> ignore

    lastState.Value.progress |> should equal <| Busy 8
    lastState.Value.maskedWord |> should equal "___b__"
     
[<Fact(Skip = "Remove to run test")>]
let ``Getting all the letters right makes for a win`` () =
    let game = createGame "hello"
    let states = statesObservable game

    let mutable lastState = None
    states.Add(fun state -> lastState <- Some state) |> ignore

    startGame game |> ignore

    makeGuess 'b' game |> ignore

    lastState.Value.progress |> should equal <| Busy 8
    lastState.Value.maskedWord |> should equal "_____"

    makeGuess 'e' game |> ignore

    lastState.Value.progress |> should equal <| Busy 8
    lastState.Value.maskedWord |> should equal "_e___"

    makeGuess 'l' game |> ignore

    lastState.Value.progress |> should equal <| Busy 8
    lastState.Value.maskedWord |> should equal "_ell_"

    makeGuess 'o' game |> ignore

    lastState.Value.progress |> should equal <| Busy 8
    lastState.Value.maskedWord |> should equal "_ello"

    makeGuess 'h' game |> ignore

    lastState.Value.progress |> should equal Win
    lastState.Value.maskedWord |> should equal "hello"
module Hangman
open System

type Progress = 
    | Busy of int
    | Win
    | Lose

type State = { progress: Progress; maskedWord: string }

type HangmanGame (word:string) =

    let word = word |> Seq.toList
    let guess = new Event<char>()
    let stateChange = new Event<State>()

    let initialState = { 
        maskedWord = word |> Seq.map (fun _ -> '_') |> String.Concat; 
        progress = Busy 9 
    }

    let advanceGame (state:State) (c:char) =
        match state.progress with
        | Win | Lose -> state
        | Busy n ->
            if state.maskedWord.Contains (string c) || Seq.contains c word |> not then
                let newProgress = n - 1
                { state with progress = if newProgress = 0 then Lose else Busy newProgress }
            else
                let indexes = [0..word.Length - 1] |> List.filter (fun i -> word.[i] = c)
                let newWord = 
                    state.maskedWord 
                    |> Seq.mapi (fun i cs -> if List.contains i indexes then c else cs) 
                    |> String.Concat
                if newWord.Contains "_" then
                    { state with maskedWord = newWord }
                else
                    { state with maskedWord = newWord; progress = Win }

    member _this.Guess c = guess.Trigger c
    member _this.StateChange = stateChange.Publish

    member _this.Start = 
        stateChange.Trigger initialState
        guess.Publish
        |> Event.scan advanceGame initialState
        |> Observable.add (stateChange.Trigger)

let createGame word = new HangmanGame (word)

let statesObservable (game: HangmanGame) = game.StateChange

let startGame (game: HangmanGame) = game.Start

let makeGuess c (game: HangmanGame) = game.Guess c

Community comments

Find this solution interesting? Ask the author a question to learn more.
Avatar of ChrisPritchard

Amusingly very similar to @jovaneyck's solution, I discovered after publishing

What can you learn from this solution?

A huge amount can be learned from reading other people’s code. This is why we wanted to give exercism users the option of making their solutions public.

Here are some questions to help you reflect on this solution and learn the most from it.

  • What compromises have been made?
  • Are there new concepts here that you could read more about to improve your understanding?