Published at Jun 29 2019
·
0 comments

Instructions

Test suite

Solution

The Collatz Conjecture or 3x+1 problem can be summarized as follows:

Take any positive integer n. If n is even, divide n by 2 to get n / 2. If n is odd, multiply n by 3 and add 1 to get 3n + 1. Repeat the process indefinitely. The conjecture states that no matter which number you start with, you will always reach 1 eventually.

Given a number n, return the number of steps required to reach 1.

Starting with n = 12, the steps would be as follows:

- 12
- 6
- 3
- 10
- 5
- 16
- 8
- 4
- 2
- 1

Resulting in 9 steps. So for input n = 12, the return value would be 9.

Execute the tests with:

```
$ mix test
```

In the test suites, all but the first test have been skipped.

Once you get a test passing, you can unskip the next one by
commenting out the relevant `@tag :pending`

with a `#`

symbol.

For example:

```
# @tag :pending
test "shouting" do
assert Bob.hey("WATCH OUT!") == "Whoa, chill out!"
end
```

Or, you can enable all the tests by commenting out the
`ExUnit.configure`

line in the test suite.

```
# ExUnit.configure exclude: :pending, trace: true
```

If you're stuck on something, it may help to look at some of the available resources out there where answers might be found.

An unsolved problem in mathematics named after mathematician Lothar Collatz https://en.wikipedia.org/wiki/3x_%2B_1_problem

It's possible to submit an incomplete solution so you can see how others have completed the exercise.

```
defmodule CollatzConjectureTest do
use ExUnit.Case
test "zero steps for one" do
assert CollatzConjecture.calc(1) == 0
end
@tag :pending
test "zero is an error" do
assert_raise FunctionClauseError, fn -> CollatzConjecture.calc(0) end
end
@tag :pending
test "divide if even" do
assert CollatzConjecture.calc(16) == 4
end
@tag :pending
test "even and odd steps" do
assert CollatzConjecture.calc(12) == 9
end
@tag :pending
test "Large number of even and odd steps" do
assert CollatzConjecture.calc(1_000_000) == 152
end
@tag :pending
test "start with odd step" do
assert CollatzConjecture.calc(21) == 7
end
@tag :pending
test "more steps than starting number" do
assert CollatzConjecture.calc(7) == 16
end
@tag :pending
test "negative value is an error " do
assert_raise FunctionClauseError, fn -> CollatzConjecture.calc(-15) end
end
@tag :pending
test "string as input value is an error " do
assert_raise FunctionClauseError, fn -> CollatzConjecture.calc("fubar") end
end
end
```

```
ExUnit.start()
ExUnit.configure(exclude: :pending, trace: true)
```

```
defmodule CollatzConjecture do
@initial_steps 0
@terminating_number 1
require Integer
defguardp positive_integer?(input) when is_integer(input) and input > 0
@doc """
calc/1 takes an integer and returns the number of steps required to get the
number to 1 when following the rules:
- if number is odd, multiply with 3 and add 1
- if number is even, divide by 2
"""
@spec calc(input :: pos_integer()) :: non_neg_integer()
def calc(input) when positive_integer?(input), do: calc(input, @initial_steps)
defp calc(@terminating_number, steps), do: steps
defp calc(input, steps) when Integer.is_even(input) do
input
|> n_div_two()
|> calc(steps + 1)
end
defp calc(input, steps) do
input
|> three_n_plus_one()
|> calc(steps + 1)
end
defp n_div_two(n), do: div(n, 2)
defp three_n_plus_one(n), do: 3 * n + 1
end
```

A huge amount can be learned from reading other people’s code. This is why we wanted to give exercism users the option of making their solutions public.

Here are some questions to help you reflect on this solution and learn the most from it.

- What compromises have been made?
- Are there new concepts here that you could read more about to improve your understanding?

Level up your programming skills with 3,373 exercises across 50 languages, and insightful discussion with our volunteer team of welcoming mentors.
Exercism is
**100% free forever**.

## Community comments