Exercism v3 launches on Sept 1st 2021. Learn more! ๐Ÿš€๐Ÿš€๐Ÿš€
Avatar of amoradell

amoradell's solution

to Saddle Points in the Delphi Pascal Track

Published at Jul 13 2018 · 0 comments
Instructions
Test suite
Solution

Note:

This solution was written on an old version of Exercism. The tests below might not correspond to the solution code, and the exercise may have changed since this code was written.

Detect saddle points in a matrix.

So say you have a matrix like so:

    0  1  2
  |---------
0 | 9  8  7
1 | 5  3  2     <--- saddle point at (1,0)
2 | 6  6  7

It has a saddle point at (1, 0).

It's called a "saddle point" because it is greater than or equal to every element in its row and less than or equal to every element in its column.

A matrix may have zero or more saddle points.

Your code should be able to provide the (possibly empty) list of all the saddle points for any given matrix.

Note that you may find other definitions of matrix saddle points online, but the tests for this exercise follow the above unambiguous definition.

Testing

In order to run the tests for this track, you will need to install DUnitX. Please see the installation instructions for more information.

Loading Exercises into Delphi

If Delphi is properly installed, and *.dpr file types have been associated with Delphi, then double clicking the supplied *.dpr file will start Delphi and load the exercise/project. control + F9 is the keyboard shortcut to compile the project or pressing F9 will compile and run the project.

Alternatively you may opt to start Delphi and load your project via. the File drop down menu.

When Questions Come Up

We monitor the Pascal-Delphi support room on gitter.im to help you with any questions that might arise.

Submitting Exercises

Note that, when trying to submit an exercise, make sure the exercise file you're submitting is in the exercism/delphi/<exerciseName> directory.

For example, if you're submitting ubob.pas for the Bob exercise, the submit command would be something like exercism submit <path_to_exercism_dir>/delphi/bob/ubob.pas.

Source

J Dalbey's Programming Practice problems http://users.csc.calpoly.edu/~jdalbey/103/Projects/ProgrammingPractice.html

Submitting Incomplete Solutions

It's possible to submit an incomplete solution so you can see how others have completed the exercise.

uSaddlePointsTests.pas

//******************************************************************
// Hint: You will be using TTuple in your solution.  TTuple is
// declared in this unit.  It will be necessary for you to add
// a uses statement in the interface section of uSaddlePoints.pas.
//
// For more guidance as you work on this exercise, see
// GETTING_STARTED.md.
//******************************************************************

unit uSaddlePointsTests;

interface
uses
  DUnitX.TestFramework;

const
  CanonicalVersion = '1.1.0';

type

  [TestFixture]
  TSaddlePointTests = class(TObject)
  public
    [Test]
//    [Ignore('Comment the "[Ignore]" statement to run the test')]
    procedure Can_identify_single_saddle_point;

    [Test]
    [Ignore]
    procedure Can_identify_that_empty_matrix_has_no_saddle_points;

    [Test]
    [Ignore]
    procedure Can_identify_lack_of_saddle_points_when_there_are_none;

    [Test]
    [Ignore]
    procedure Can_identify_multiple_saddle_points;

    [Test]
    [Ignore]
    procedure Can_identify_saddle_point_in_bottom_right_corner;
  end;

  TTuple<T1, T2> = record
  private
    fValue1: T1;
    fValue2: T2;
  public
    constructor Create(Value1: T1; Value2: T2);
    property Value1 : T1 read fValue1;
    property Value2 : T2 read fValue2;
  end;

implementation
uses uSaddlePoints;

constructor TTuple<T1, T2>.Create(Value1: T1; Value2: T2);
begin
  fValue1 := Value1;
  fValue2 := Value2;
end;

procedure TSaddlePointTests.Can_identify_single_saddle_point;
var SaddlePoints: ISaddlePoints;
    values: TArray<TArray<integer>>;
    expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, 3, 3);
  values[0,0] := 9; values[0,1] := 8; values[0,2] := 7;
  values[1,0] := 5; values[1,1] := 3; values[1,2] := 2;
  values[2,0] := 6; values[2,1] := 6; values[2,2] := 7;

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 1);
  expected[0] := TTuple<integer,integer>.Create(1,0);
  Assert.AreEqual(expected,SaddlePoints.Calculate);
end;

procedure TSaddlePointTests.Can_identify_that_empty_matrix_has_no_saddle_points;
var SaddlePoints: ISaddlePoints;
    values: TArray<TArray<integer>>;
    expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, 0, 0);

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 0);
  Assert.AreEqual(expected,SaddlePoints.Calculate);
end;

procedure TSaddlePointTests.Can_identify_lack_of_saddle_points_when_there_are_none;
var SaddlePoints: ISaddlePoints;
    values: TArray<TArray<integer>>;
    expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, 3, 3);
  values[0,0] := 1; values[0,1] := 2; values[0,2] := 3;
  values[1,0] := 3; values[1,1] := 1; values[1,2] := 2;
  values[2,0] := 2; values[2,1] := 3; values[2,2] := 1;

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 0);
  Assert.AreEqual(expected,SaddlePoints.Calculate);
end;

procedure TSaddlePointTests.Can_identify_multiple_saddle_points;
var SaddlePoints: ISaddlePoints;
    values: TArray<TArray<integer>>;
    expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, 3, 3);
  values[0,0] := 4; values[0,1] := 5; values[0,2] := 4;
  values[1,0] := 3; values[1,1] := 5; values[1,2] := 5;
  values[2,0] := 1; values[2,1] := 5; values[2,2] := 4;

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 3);
  expected[0] := TTuple<integer,integer>.Create(0,1);
  expected[1] := TTuple<integer,integer>.Create(1,1);
  expected[2] := TTuple<integer,integer>.Create(2,1);
  Assert.AreEqual(expected,SaddlePoints.Calculate);
end;

procedure TSaddlePointTests.Can_identify_saddle_point_in_bottom_right_corner;
var SaddlePoints: ISaddlePoints;
    values: TArray<TArray<integer>>;
    expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, 3, 3);
  values[0,0] := 8; values[0,1] := 7; values[0,2] := 9;
  values[1,0] := 6; values[1,1] := 7; values[1,2] := 6;
  values[2,0] := 3; values[2,1] := 2; values[2,2] := 5;

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 1);
  expected[0] := TTuple<integer,integer>.Create(2,2);
  Assert.AreEqual(expected,SaddlePoints.Calculate);
end;

initialization
  TDUnitX.RegisterTestFixture(TSaddlePointTests);
end.
unit uSaddlePoints;

interface

uses
  uSaddlePointsTests;

type
  ISaddlePoints = interface
    ['{CCD2CAC9-8B71-4EB7-AE1E-8180F7C92260}']
    function Calculate:TArray<TTuple<integer,integer>>;
  end;

  function newSaddlePoints(aValues:TArray<TArray<integer>>):ISaddlePoints;

implementation

uses
  System.Generics.Collections;

type
  TSaddlePoints = class(TInterfacedObject, ISaddlePoints)
  private
    FValues: TArray<TArray<integer>>;
    FNominees: TList<TTuple<integer,integer>>;
    procedure FillNominees;
  public
    function Calculate: TArray<TTuple<integer,integer>>;
    constructor Create(aValues:TArray<TArray<integer>>);
    destructor Destroy; override;
  end;

function newSaddlePoints(aValues:TArray<TArray<integer>>):ISaddlePoints;
begin
  result := TSaddlePoints.Create(aValues);
end;

constructor TSaddlePoints.Create(aValues: TArray<TArray<integer>>);
begin
  inherited Create;
  FValues := aValues;
  FNominees := TList<TTuple<integer,integer>>.Create();
  FillNominees;
end;

procedure  TSaddlePoints.FillNominees;
var
  zArrayMaxRow: TArray<integer>;
  i, MaxValue: integer;

  function RowMaxValue: integer;
  var aCol:integer;
  begin
    result := 0;
    for aCol := Low(zArrayMaxRow) to High(zArrayMaxRow) do
    begin
      if (zArrayMaxRow[aCol] >= result) then
        result := zArrayMaxRow[aCol];
    end;
  end;

  procedure AddMaxValueToFNominees(aRow, aMaxValue:integer);
  var aCol:integer;
  begin
    for aCol := Low(zArrayMaxRow) to High(zArrayMaxRow) do
    begin
      if (zArrayMaxRow[aCol] = aMaxValue) then
        FNominees.Add(TTuple<integer,integer>.Create(aRow, aCol));
    end;
  end;

begin
  for i := Low(FValues) to High(FValues) do
  begin
    zArrayMaxRow := FValues[i];
    MaxValue := RowMaxValue;
    AddMaxValueToFNominees(i, MaxValue);
  end;
end;

destructor TSaddlePoints.Destroy;
begin
  FNominees.Free;
end;

function  TSaddlePoints.Calculate:TArray<TTuple<integer,integer>>;
var
  zSaddlePointsLaureates: TArray<TTuple<integer,integer>> ;
  zPoint: TTuple<integer,integer>;
  zArrayMinCol: TArray<integer>;
  i,j, MaxValue: integer;
  isMaxRowisMinCol:boolean;
begin
// It's called a "saddle point" because it is greater than or equal to
// every element in its row and the less than or equal to every element in
// its column.
  for i := 0 to pred(FNominees.count) do
  begin
    zPoint := FNominees.Items[i];
    MaxValue := FValues[zPoint.Value1][zPoint.Value2];
    isMaxRowIsMinCol := true;
    for j := Low(FValues) to High(FValues) do
    begin
      if (j <> zPoint.Value1) then
      begin
        zArrayMinCol := FValues[j];
        if (MaxValue > zArrayMinCol[zPoint.Value2]) then
        begin
          IsMaxRowIsMinCol := false;
          break;
        end;
      end;
    end;
    if ( IsMaxRowIsMinCol ) then
    begin
      SetLength(zSaddlePointsLaureates, Length(zSaddlePointsLaureates) + 1);
      zSaddlePointsLaureates[High(zSaddlePointsLaureates)] := FNominees.Items[i];
    end;
  end;
  result := zSaddlePointsLaureates;
end;


end.

Community comments

Find this solution interesting? Ask the author a question to learn more.

What can you learn from this solution?

A huge amount can be learned from reading other peopleโ€™s code. This is why we wanted to give exercism users the option of making their solutions public.

Here are some questions to help you reflect on this solution and learn the most from it.

  • What compromises have been made?
  • Are there new concepts here that you could read more about to improve your understanding?