Creating a zipper for a binary tree.
Zippers are a purely functional way of navigating within a data structure and manipulating it. They essentially contain a data structure and a pointer into that data structure (called the focus).
For example given a rose tree (where each node contains a value and a list of child nodes) a zipper might support these operations:
from_tree
(get a zipper out of a rose tree, the focus is on the root node)to_tree
(get the rose tree out of the zipper)value
(get the value of the focus node)prev
(move the focus to the previous child of the same parent,
returns a new zipper)next
(move the focus to the next child of the same parent, returns a
new zipper)up
(move the focus to the parent, returns a new zipper)set_value
(set the value of the focus node, returns a new zipper)insert_before
(insert a new subtree before the focus node, it
becomes the prev
of the focus node, returns a new zipper)insert_after
(insert a new subtree after the focus node, it becomes
the next
of the focus node, returns a new zipper)delete
(removes the focus node and all subtrees, focus moves to the
next
node if possible otherwise to the prev
node if possible,
otherwise to the parent node, returns a new zipper)Please refer to the installation and learning help pages.
To run the test suite, execute the following command:
stack test
No .cabal file found in directory
You are probably running an old stack version and need to upgrade it.
No compiler found, expected minor version match with...
Try running "stack setup" to install the correct GHC...
Just do as it says and it will download and install the correct compiler version:
stack setup
If you want to play with your solution in GHCi, just run the command:
stack ghci
The exercism/haskell repository on GitHub is the home for all of the Haskell exercises.
If you have feedback about an exercise, or want to help implementing a new one, head over there and create an issue. We'll do our best to help you!
It's possible to submit an incomplete solution so you can see how others have completed the exercise.
import Data.Maybe (fromJust)
import Test.Hspec (Spec, it, shouldBe)
import Test.Hspec.Runner (configFastFail, defaultConfig, hspecWith)
import Zipper
( BinTree(BT)
, fromTree
, left
, right
, setLeft
, setRight
, setValue
, toTree
, up
, value
)
main :: IO ()
main = hspecWith defaultConfig {configFastFail = True} specs
specs :: Spec
specs = do
let leaf v = node v Nothing Nothing
node v l r = Just (BT v l r :: BinTree Int)
t1 = BT 1 (node 2 Nothing $ leaf 3) $ leaf 4
t2 = BT 1 (node 5 Nothing $ leaf 3) $ leaf 4
t3 = BT 1 (node 2 (leaf 5) $ leaf 3) $ leaf 4
t4 = BT 1 (leaf 2 ) $ leaf 4
t5 = BT 6 (leaf 7 ) $ leaf 8
t6 = BT 1 (node 2 Nothing $ leaf 3) $ node 6 (leaf 7) (leaf 8)
t7 = BT 1 (node 2 Nothing $ leaf 5) $ leaf 4
it "data is retained" $
toTree (fromTree t1)
`shouldBe` t1
it "left, right and value" $
(value . fromJust . right . fromJust . left . fromTree) t1
`shouldBe` 3
it "dead end" $
(left . fromJust . left . fromTree) t1
`shouldBe` Nothing
it "traversing up from top" $
(up . fromTree) t1
`shouldBe` Nothing
it "left, right, and up" $
(value . fromJust . right . fromJust . left . fromJust . up . fromJust . right . fromJust . up . fromJust . left . fromTree) t1
`shouldBe` 3
it "tree from deep focus" $
(toTree . fromJust . right . fromJust . left . fromTree) t1
`shouldBe` t1
it "setValue" $
(toTree . setValue 5 . fromJust . left . fromTree) t1
`shouldBe` t2
it "setValue after traversing up" $
(toTree . setValue 5 . fromJust . up . fromJust . right . fromJust . left . fromTree) t1
`shouldBe` t2
it "setLeft with Just" $
(toTree . setLeft (leaf 5) . fromJust . left . fromTree) t1
`shouldBe` t3
it "setRight with Nothing" $
(toTree . setRight Nothing . fromJust . left . fromTree) t1
`shouldBe` t4
it "setRight with subtree" $
(toTree . setRight (Just t5) . fromTree) t1
`shouldBe` t6
it "setValue on deep focus" $
(toTree . setValue 5 . fromJust . right . fromJust . left . fromTree) t1
`shouldBe` t7
it "different paths to same zipper" $
(right . fromJust . up . fromJust . left . fromTree) t1
`shouldBe` (right . fromTree) t1
{-# LANGUAGE LambdaCase #-}
{-# LANGUAGE TypeApplications #-}
module Zipper
( BinTree(BT)
, fromTree
, left
, right
, setLeft
, setRight
, setValue
, toTree
, up
, value
) where
import Data.Bool (bool)
import Data.List (init)
import Data.Maybe (fromMaybe)
import Optics (AffineTraversal', An_AffineTraversal, Lens', castOptic, equality,
lens, view, (%), (&), (.~), (^?), _Just)
data BinTree a = BT { btValue :: a
, btLeft :: Maybe (BinTree a)
, btRight :: Maybe (BinTree a)
} deriving (Eq, Show)
data Zipper a =
Zipper (BinTree a) Focus
deriving (Eq, Show)
type Focus = [Bool]
fromTree :: BinTree a -> Zipper a
fromTree tree = Zipper tree []
toTree :: Zipper a -> BinTree a
toTree = view _Tree
value :: Zipper a -> a
value (Zipper tree f) =
fromMaybe
(error "Bad Focus")
$ tree ^? focusing f % _Value
left :: Zipper a -> Maybe (Zipper a)
left (Zipper tree f) =
Zipper tree (f <> [False]) <$ tree ^? focusing f % _LeftTree % _Just
right :: Zipper a -> Maybe (Zipper a)
right (Zipper tree f) =
Zipper tree (f <> [True]) <$ tree ^? focusing f % _RightTree % _Just
up :: Zipper a -> Maybe (Zipper a)
up = \case
Zipper _ [] -> Nothing
Zipper tree f -> pure $ Zipper tree $ init f
setValue :: a -> Zipper a -> Zipper a
setValue x zipper@(Zipper _ f) = zipper & _Tree % focusing f % _Value .~ x
setLeft :: Maybe (BinTree a) -> Zipper a -> Zipper a
setLeft tree zipper@(Zipper _ f) = zipper & _Tree % focusing f % _LeftTree .~ tree
setRight :: Maybe (BinTree a) -> Zipper a -> Zipper a
setRight tree zipper@(Zipper _ f) = zipper & _Tree % focusing f % _RightTree .~ tree
_Value :: Lens' (BinTree a) a
_Value = lens btValue (\s a -> s { btValue = a })
_LeftTree :: Lens' (BinTree a) (Maybe (BinTree a))
_LeftTree = lens btLeft (\s a -> s { btLeft = a })
_RightTree :: Lens' (BinTree a) (Maybe (BinTree a))
_RightTree = lens btRight (\s a -> s { btRight = a })
_Tree :: Lens' (Zipper a) (BinTree a)
_Tree = lens (\(Zipper tree _) -> tree) (\(Zipper _ f) a -> Zipper a f)
focusing :: [Bool] -> AffineTraversal' (BinTree a) (BinTree a)
focusing bs =
foldr (%) (castOptic @An_AffineTraversal equality)
$ bool (_LeftTree % _Just) (_RightTree % _Just) <$> bs
A huge amount can be learned from reading other peopleâ€™s code. This is why we wanted to give exercism users the option of making their solutions public.
Here are some questions to help you reflect on this solution and learn the most from it.
Level up your programming skills with 3,450 exercises across 52 languages, and insightful discussion with our volunteer team of welcoming mentors. Exercism is 100% free forever.
Sign up Learn More
Community comments
Using optics to view, traverse and update a tree.