ðŸŽ‰ Exercism Research is now launched. Help Exercism, help science and have some fun at research.exercism.io ðŸŽ‰

qfjp's solution

to Zipper in the Haskell Track

Published at Dec 08 2019 · 0 comments
Instructions
Test suite
Solution

Note:

This exercise has changed since this solution was written.

Creating a zipper for a binary tree.

Zippers are a purely functional way of navigating within a data structure and manipulating it. They essentially contain a data structure and a pointer into that data structure (called the focus).

For example given a rose tree (where each node contains a value and a list of child nodes) a zipper might support these operations:

• `from_tree` (get a zipper out of a rose tree, the focus is on the root node)
• `to_tree` (get the rose tree out of the zipper)
• `value` (get the value of the focus node)
• `prev` (move the focus to the previous child of the same parent, returns a new zipper)
• `next` (move the focus to the next child of the same parent, returns a new zipper)
• `up` (move the focus to the parent, returns a new zipper)
• `set_value` (set the value of the focus node, returns a new zipper)
• `insert_before` (insert a new subtree before the focus node, it becomes the `prev` of the focus node, returns a new zipper)
• `insert_after` (insert a new subtree after the focus node, it becomes the `next` of the focus node, returns a new zipper)
• `delete` (removes the focus node and all subtrees, focus moves to the `next` node if possible otherwise to the `prev` node if possible, otherwise to the parent node, returns a new zipper)

Getting Started

Please refer to the installation and learning help pages.

Running the tests

To run the test suite, execute the following command:

``````stack test
``````

If you get an error message like this...

``````No .cabal file found in directory
``````

You are probably running an old stack version and need to upgrade it.

Otherwise, if you get an error message like this...

``````No compiler found, expected minor version match with...
Try running "stack setup" to install the correct GHC...
``````

Just do as it says and it will download and install the correct compiler version:

``````stack setup
``````

Running GHCi

If you want to play with your solution in GHCi, just run the command:

``````stack ghci
``````

Feedback, Issues, Pull Requests

The exercism/haskell repository on GitHub is the home for all of the Haskell exercises.

If you have feedback about an exercise, or want to help implementing a new one, head over there and create an issue. We'll do our best to help you!

Submitting Incomplete Solutions

It's possible to submit an incomplete solution so you can see how others have completed the exercise.

Tests.hs

``````import Data.Maybe        (fromJust)
import Test.Hspec        (Spec, it, shouldBe)
import Test.Hspec.Runner (configFastFail, defaultConfig, hspecWith)

import Zipper
( BinTree(BT)
, fromTree
, left
, right
, setLeft
, setRight
, setValue
, toTree
, up
, value
)

main :: IO ()
main = hspecWith defaultConfig {configFastFail = True} specs

specs :: Spec
specs = do

let leaf v     = node v Nothing Nothing
node v l r = Just (BT v l r :: BinTree Int)
t1         = BT 1 (node 2 Nothing  \$ leaf 3) \$ leaf 4
t2         = BT 1 (node 5 Nothing  \$ leaf 3) \$ leaf 4
t3         = BT 1 (node 2 (leaf 5) \$ leaf 3) \$ leaf 4
t4         = BT 1 (leaf 2                  ) \$ leaf 4
t5         = BT 6 (leaf 7                  ) \$ leaf 8
t6         = BT 1 (node 2 Nothing  \$ leaf 3) \$ node 6 (leaf 7) (leaf 8)
t7         = BT 1 (node 2 Nothing  \$ leaf 5) \$ leaf 4

it "data is retained" \$
toTree (fromTree t1)
`shouldBe` t1

it "left, right and value" \$
(value . fromJust . right . fromJust . left . fromTree) t1
`shouldBe` 3

(left . fromJust . left . fromTree) t1
`shouldBe` Nothing

it "traversing up from top" \$
(up . fromTree) t1
`shouldBe` Nothing

it "left, right, and up" \$
(value . fromJust . right . fromJust . left . fromJust . up . fromJust . right . fromJust . up . fromJust . left . fromTree) t1
`shouldBe` 3

it "tree from deep focus" \$
(toTree . fromJust . right . fromJust . left . fromTree) t1
`shouldBe` t1

it "setValue" \$
(toTree . setValue 5 . fromJust . left . fromTree) t1
`shouldBe` t2

it "setValue after traversing up" \$
(toTree . setValue 5 . fromJust . up . fromJust . right . fromJust . left . fromTree) t1
`shouldBe` t2

it "setLeft with Just" \$
(toTree . setLeft (leaf 5) . fromJust . left . fromTree) t1
`shouldBe` t3

it "setRight with Nothing" \$
(toTree . setRight Nothing . fromJust . left . fromTree) t1
`shouldBe` t4

it "setRight with subtree" \$
(toTree . setRight (Just t5) . fromTree) t1
`shouldBe` t6

it "setValue on deep focus" \$
(toTree . setValue 5 . fromJust . right . fromJust . left . fromTree) t1
`shouldBe` t7

it "different paths to same zipper" \$
(right . fromJust . up . fromJust . left . fromTree) t1
`shouldBe` (right . fromTree) t1``````
``````module Zipper
( BinTree(BT)
, fromTree
, left
, right
, setLeft
, setRight
, setValue
, toTree
, up
, value
) where

type MaybTree a = Maybe (BinTree a)

data BinTree a =
BT
{ btValue :: a
, btLeft  :: MaybTree a
, btRight :: MaybTree a
}
deriving (Eq, Show)

data Cxt a
= L a (MaybTree a)
| R a (MaybTree a)
deriving (Eq, Show)

data Zipper a =
Z (BinTree a) [Cxt a]
deriving (Eq, Show)

fromTree :: BinTree a -> Zipper a
fromTree tree = Z tree []

toTree :: Zipper a -> BinTree a
toTree z@(Z t _) =
case up z of
Nothing -> t
Just z' -> toTree z'

value :: Zipper a -> a
value (Z (BT x _ _) _) = x

left :: Zipper a -> Maybe (Zipper a)
left (Z (BT x l r) bs) =
case l of
Nothing -> Nothing
Just l' -> Just (Z l' (L x r : bs))

right :: Zipper a -> Maybe (Zipper a)
right (Z (BT x l r) bs) =
case r of
Nothing -> Nothing
Just r' -> Just (Z r' (R x l : bs))

up :: Zipper a -> Maybe (Zipper a)
up (Z t ((L x r):bs)) = Just \$ Z (BT x (Just t) r) bs
up (Z t ((R x l):bs)) = Just \$ Z (BT x l (Just t)) bs
up _                  = Nothing

setValue :: a -> Zipper a -> Zipper a
setValue x (Z (BT _ l r) cs) = Z (BT x l r) cs

setLeft :: Maybe (BinTree a) -> Zipper a -> Zipper a
setLeft l (Z (BT x _ r) cs) = Z (BT x l r) cs

setRight :: Maybe (BinTree a) -> Zipper a -> Zipper a
setRight r (Z (BT x l _) cs) = Z (BT x l r) cs``````