🎉 Exercism Research is now launched. Help Exercism, help science and have some fun at research.exercism.io 🎉
Avatar of HarrisonMc555

HarrisonMc555's solution

to Matching Brackets in the Elm Track

Published at Jun 13 2020 · 0 comments
Instructions
Test suite
Solution

Given a string containing brackets [], braces {}, parentheses (), or any combination thereof, verify that any and all pairs are matched and nested correctly.

Elm Installation

Refer to the Installing Elm page for information about installing elm.

Writing the Code

The code you have to write is located inside the src/ directory of the exercise. Elm automatically installs packages dependencies the first time you run the tests so we can start by running the tests from the exercise directory with:

$ elm-test

To automatically run tests again when you save changes:

$ elm-test --watch

As you work your way through the tests suite in the file tests/Tests.elm, be sure to remove the skip <| calls from each test until you get them all passing!

Source

Ginna Baker

Submitting Incomplete Solutions

It is possible to submit an incomplete solution so you can see how others have completed the exercise.

Tests.elm

module Tests exposing (tests)

import Expect
import MatchingBrackets exposing (isPaired)
import String
import Test exposing (..)


tests : Test
tests =
    describe "MatchingBrackets"
        [ test "paired square brackets" <|
            \_ ->
                Expect.equal True (isPaired "[]")
        , skip <|
            test "empty string" <|
                \_ ->
                    Expect.equal True (isPaired "")
        , skip <|
            test "unpaired brackets" <|
                \_ ->
                    Expect.equal False (isPaired "[[")
        , skip <|
            test "wrong ordered brackets" <|
                \_ ->
                    Expect.equal False (isPaired "}{")
        , skip <|
            test "wrong closing bracket" <|
                \_ ->
                    Expect.equal False (isPaired "{]")
        , skip <|
            test "paired with whitespace" <|
                \_ ->
                    Expect.equal True (isPaired "{ }")
        , skip <|
            test "partially paired brackets" <|
                \_ ->
                    Expect.equal False (isPaired "{[])")
        , skip <|
            test "simple nested brackets" <|
                \_ ->
                    Expect.equal True (isPaired "{[]}")
        , skip <|
            test "seceral paired brackets" <|
                \_ ->
                    Expect.equal True (isPaired "{}[]")
        , skip <|
            test "paired and nested brackets" <|
                \_ ->
                    Expect.equal True (isPaired "([{}({}[])])")
        , skip <|
            test "unopened closing brackets" <|
                \_ ->
                    Expect.equal False (isPaired "{[)][]}")
        , skip <|
            test "unpaired and nested brackets" <|
                \_ ->
                    Expect.equal False (isPaired "([{])")
        , skip <|
            test "paired and wrong nested brackets" <|
                \_ ->
                    Expect.equal False (isPaired "[({]})")
        , skip <|
            test "math expression" <|
                \_ ->
                    Expect.equal True (isPaired "(((185 + 223.85) * 15) - 543)/2")
        , skip <|
            test "complex latex expression" <|
                \_ ->
                    Expect.equal True (isPaired "\\left(\\begin{array}{cc} \\frac{1}{3} & x\\\\ \\mathrm{e}^{x} &... x^2 \\end{array}\\right)")
        ]
module MatchingBrackets exposing (isPaired)

import Dict exposing (Dict)
import Set exposing (Set)


isPaired : String -> Bool
isPaired input =
    isPairedHelper (String.toList input) []


isPairedHelper : List Char -> List Char -> Bool
isPairedHelper chars stack =
    case chars of
        char :: restChars ->
            if isClosing char then
                case stack of
                    stackClosingChar :: restStack ->
                        if stackClosingChar == char then
                            isPairedHelper restChars restStack

                        else
                            False

                    [] ->
                        False

            else
                case openToClose char of
                    Just close ->
                        isPairedHelper restChars (close :: stack)

                    Nothing ->
                        isPairedHelper restChars stack

        [] ->
            List.isEmpty stack


openToClose : Char -> Maybe Char
openToClose c =
    Dict.get c bracketPairs


isClosing : Char -> Bool
isClosing c =
    Set.member c closingBrackets


bracketPairs : Dict Char Char
bracketPairs =
    [ ( '(', ')' )
    , ( '[', ']' )
    , ( '{', '}' )
    ]
        |> Dict.fromList


closingBrackets : Set Char
closingBrackets =
    Dict.values bracketPairs
        |> Set.fromList

Community comments

Find this solution interesting? Ask the author a question to learn more.

What can you learn from this solution?

A huge amount can be learned from reading other people’s code. This is why we wanted to give exercism users the option of making their solutions public.

Here are some questions to help you reflect on this solution and learn the most from it.

  • What compromises have been made?
  • Are there new concepts here that you could read more about to improve your understanding?