🎉 Exercism Research is now launched. Help Exercism, help science and have some fun at research.exercism.io 🎉
Avatar of przemyslawhaptas

przemyslawhaptas's solution

to Matching Brackets in the Elm Track

Published at Jan 04 2020 · 0 comments
Instructions
Test suite
Solution

Given a string containing brackets [], braces {}, parentheses (), or any combination thereof, verify that any and all pairs are matched and nested correctly.

Elm Installation

Refer to the Installing Elm page for information about installing elm.

Writing the Code

The code you have to write is located inside the src/ directory of the exercise. Elm automatically installs packages dependencies the first time you run the tests so we can start by running the tests from the exercise directory with:

$ elm-test

To automatically run tests again when you save changes:

$ elm-test --watch

As you work your way through the tests suite in the file tests/Tests.elm, be sure to remove the skip <| calls from each test until you get them all passing!

Source

Ginna Baker

Submitting Incomplete Solutions

It is possible to submit an incomplete solution so you can see how others have completed the exercise.

Tests.elm

module Tests exposing (tests)

import Expect
import MatchingBrackets exposing (isPaired)
import String
import Test exposing (..)


tests : Test
tests =
    describe "MatchingBrackets"
        [ test "paired square brackets" <|
            \_ ->
                Expect.equal True (isPaired "[]")
        , skip <|
            test "empty string" <|
                \_ ->
                    Expect.equal True (isPaired "")
        , skip <|
            test "unpaired brackets" <|
                \_ ->
                    Expect.equal False (isPaired "[[")
        , skip <|
            test "wrong ordered brackets" <|
                \_ ->
                    Expect.equal False (isPaired "}{")
        , skip <|
            test "wrong closing bracket" <|
                \_ ->
                    Expect.equal False (isPaired "{]")
        , skip <|
            test "paired with whitespace" <|
                \_ ->
                    Expect.equal True (isPaired "{ }")
        , skip <|
            test "partially paired brackets" <|
                \_ ->
                    Expect.equal False (isPaired "{[])")
        , skip <|
            test "simple nested brackets" <|
                \_ ->
                    Expect.equal True (isPaired "{[]}")
        , skip <|
            test "seceral paired brackets" <|
                \_ ->
                    Expect.equal True (isPaired "{}[]")
        , skip <|
            test "paired and nested brackets" <|
                \_ ->
                    Expect.equal True (isPaired "([{}({}[])])")
        , skip <|
            test "unopened closing brackets" <|
                \_ ->
                    Expect.equal False (isPaired "{[)][]}")
        , skip <|
            test "unpaired and nested brackets" <|
                \_ ->
                    Expect.equal False (isPaired "([{])")
        , skip <|
            test "paired and wrong nested brackets" <|
                \_ ->
                    Expect.equal False (isPaired "[({]})")
        , skip <|
            test "math expression" <|
                \_ ->
                    Expect.equal True (isPaired "(((185 + 223.85) * 15) - 543)/2")
        , skip <|
            test "complex latex expression" <|
                \_ ->
                    Expect.equal True (isPaired "\\left(\\begin{array}{cc} \\frac{1}{3} & x\\\\ \\mathrm{e}^{x} &... x^2 \\end{array}\\right)")
        ]
module MatchingBrackets exposing (isPaired)

import Dict exposing (Dict)


isPaired : String -> Bool
isPaired =
    String.toList >> isPaired_ []


isPaired_ : List Char -> List Char -> Bool
isPaired_ bracketsAcc input =
    case input of
        [] ->
            List.isEmpty bracketsAcc

        inputH :: inputT ->
            if isOpeningBracket inputH then
                isPaired_ (inputH :: bracketsAcc) inputT

            else if isClosingBracket inputH then
                case bracketsAcc of
                    [] ->
                        False

                    bracketsH :: bracketsT ->
                        if isMatchingOpeningBracket bracketsH inputH then
                            isPaired_ bracketsT inputT

                        else
                            False

            else
                isPaired_ bracketsAcc inputT


bracketTags : Dict Char Char
bracketTags =
    Dict.fromList
        [ ( '(', ')' )
        , ( '{', '}' )
        , ( '[', ']' )
        ]


isOpeningBracket : Char -> Bool
isOpeningBracket char =
    List.member char (Dict.keys bracketTags)


isClosingBracket : Char -> Bool
isClosingBracket char =
    List.member char (Dict.values bracketTags)


isMatchingOpeningBracket : Char -> Char -> Bool
isMatchingOpeningBracket openingChar closingChar =
    case Dict.get openingChar bracketTags of
        Just closingTag ->
            closingTag == closingChar

        Nothing ->
            False

What can you learn from this solution?

A huge amount can be learned from reading other people’s code. This is why we wanted to give exercism users the option of making their solutions public.

Here are some questions to help you reflect on this solution and learn the most from it.

  • What compromises have been made?
  • Are there new concepts here that you could read more about to improve your understanding?