# alpashka's solution

## to Rotational Cipher in the Elixir Track

Published at Jul 13 2018 · 5 comments
Instructions
Test suite
Solution

#### Note:

This solution was written on an old version of Exercism. The tests below might not correspond to the solution code, and the exercise may have changed since this code was written.

Create an implementation of the rotational cipher, also sometimes called the Caesar cipher.

The Caesar cipher is a simple shift cipher that relies on transposing all the letters in the alphabet using an integer key between `0` and `26`. Using a key of `0` or `26` will always yield the same output due to modular arithmetic. The letter is shifted for as many values as the value of the key.

The general notation for rotational ciphers is `ROT + <key>`. The most commonly used rotational cipher is `ROT13`.

A `ROT13` on the Latin alphabet would be as follows:

``````Plain:  abcdefghijklmnopqrstuvwxyz
Cipher: nopqrstuvwxyzabcdefghijklm
``````

It is stronger than the Atbash cipher because it has 27 possible keys, and 25 usable keys.

Ciphertext is written out in the same formatting as the input including spaces and punctuation.

## Examples

• ROT5 `omg` gives `trl`
• ROT0 `c` gives `c`
• ROT26 `Cool` gives `Cool`
• ROT13 `The quick brown fox jumps over the lazy dog.` gives `Gur dhvpx oebja sbk whzcf bire gur ynml qbt.`
• ROT13 `Gur dhvpx oebja sbk whzcf bire gur ynml qbt.` gives `The quick brown fox jumps over the lazy dog.`

## Running tests

Execute the tests with:

``````\$ elixir rotational_cipher_test.exs
``````

### Pending tests

In the test suites, all but the first test have been skipped.

Once you get a test passing, you can unskip the next one by commenting out the relevant `@tag :pending` with a `#` symbol.

For example:

``````# @tag :pending
test "shouting" do
assert Bob.hey("WATCH OUT!") == "Whoa, chill out!"
end
``````

Or, you can enable all the tests by commenting out the `ExUnit.configure` line in the test suite.

``````# ExUnit.configure exclude: :pending, trace: true
``````

For more detailed information about the Elixir track, please see the help page.

## Submitting Incomplete Solutions

It's possible to submit an incomplete solution so you can see how others have completed the exercise.

### rotational_cipher_test.exs

``````if !System.get_env("EXERCISM_TEST_EXAMPLES") do
end

ExUnit.start()
ExUnit.configure(exclude: :pending, trace: true)

defmodule RotationalCipherTest do
use ExUnit.Case

# @tag :pending
test "rotate a by 1" do
plaintext = "a"
shift = 1
assert RotationalCipher.rotate(plaintext, shift) == "b"
end

@tag :pending
test "rotate a by 26, same output as input" do
plaintext = "a"
shift = 26
assert RotationalCipher.rotate(plaintext, shift) == "a"
end

@tag :pending
test "rotate a by 0, same output as input" do
plaintext = "a"
shift = 0
assert RotationalCipher.rotate(plaintext, shift) == "a"
end

@tag :pending
test "rotate m by 13" do
plaintext = "m"
shift = 13
assert RotationalCipher.rotate(plaintext, shift) == "z"
end

@tag :pending
test "rotate n by 13 with wrap around alphabet" do
plaintext = "n"
shift = 13
assert RotationalCipher.rotate(plaintext, shift) == "a"
end

@tag :pending
test "rotate capital letters" do
plaintext = "OMG"
shift = 5
assert RotationalCipher.rotate(plaintext, shift) == "TRL"
end

@tag :pending
test "rotate spaces" do
plaintext = "O M G"
shift = 5
assert RotationalCipher.rotate(plaintext, shift) == "T R L"
end

@tag :pending
test "rotate numbers" do
plaintext = "Testing 1 2 3 testing"
shift = 4
assert RotationalCipher.rotate(plaintext, shift) == "Xiwxmrk 1 2 3 xiwxmrk"
end

@tag :pending
test "rotate punctuation" do
plaintext = "Let's eat, Grandma!"
shift = 21
assert RotationalCipher.rotate(plaintext, shift) == "Gzo'n zvo, Bmviyhv!"
end

@tag :pending
test "rotate all letters" do
plaintext = "The quick brown fox jumps over the lazy dog."
shift = 13

assert RotationalCipher.rotate(plaintext, shift) ==
"Gur dhvpx oebja sbk whzcf bire gur ynml qbt."
end
end``````
``````defmodule RotationalCipher do
@upper ?A..?Z
@lower ?a..?z
@doc """
Given a plaintext and amount to shift by, return a rotated string.

Example:
iex> RotationalCipher.rotate("Attack at dawn", 13)
"Nggnpx ng qnja"
"""
@spec rotate(text :: String.t(), shift :: integer) :: String.t()
def rotate(text, shift) do
text
|> to_charlist
|> Enum.map(
&(rotate_char(&1, shift))
)
|> to_string
end

defp rotate_char(char, shift) do
cond do
char in @upper -> rem(char - ?A + shift, 26) + ?A
char in @lower -> rem(char - ?a + shift, 26) + ?a
true           -> char
end
end
end``````

Oh man this looks superb. Although I can't wrap my head around rem(char - ?A + shift, 26) + ?A

@fhdhsni commented:

Oh man this looks superb. Although I can't wrap my head around rem(char - ?A + shift, 26) + ?A

Since ?A = 65, ?B = 66 etc...

char - ?A will mean that if the character is the letter A, that snippet will evaluate to 0, and if it's B, that will evaluate to 1, etc.

You can then add on the "shift" to determine the new offset, so if char is A and shift is 1, then char - ?A + shift would be 1. You can then add this back onto ?A (i.e 65) to get your rotated value... (char - ?A + shift) + ?A would then evaluate to ?B - i.e. shifted as expected.

However, if the char is instead ?Z and shift is 1, you've got a problem - you'd be shifting past the end of the alphabet, and we need it to "wrap". So the rem() function is used to get the remainder when dividing by 26. Take the situation where char is ?Z and shift is 1:

rem(char - ?A + shift, 26) + ?A becomes rem(?Z - ?A + 1, 26) + ?A becomes rem(25 + 1, 26) + ?A and since 26/26 leaves a remainder of 0, you end up with 0 + ?A which is ?A - i.e. the inclusion of rem() makes the wrapping work.

Hopefully that's clear enough.

@rttremaine commented:

@fhdhsni commented:

Oh man this looks superb. Although I can't wrap my head around rem(char - ?A + shift, 26) + ?A

Since ?A = 65, ?B = 66 etc...

char - ?A will mean that if the character is the letter A, that snippet will evaluate to 0, and if it's B, that will evaluate to 1, etc.

You can then add on the "shift" to determine the new offset, so if char is A and shift is 1, then char - ?A + shift would be 1. You can then add this back onto ?A (i.e 65) to get your rotated value... (char - ?A + shift) + ?A would then evaluate to ?B - i.e. shifted as expected.

However, if the char is instead ?Z and shift is 1, you've got a problem - you'd be shifting past the end of the alphabet, and we need it to "wrap". So the rem() function is used to get the remainder when dividing by 26. Take the situation where char is ?Z and shift is 1:

rem(char - ?A + shift, 26) + ?A becomes rem(?Z - ?A + 1, 26) + ?A becomes rem(25 + 1, 26) + ?A and since 26/26 leaves a remainder of 0, you end up with 0 + ?A which is ?A - i.e. the inclusion of rem() makes the wrapping work.

Hopefully that's clear enough.

Thanks. ??

The use of @upper and @lower is awesome.

The cool learning here for me is line 16, that I don't need to wrap the `rotate_char` in an anonymous function! I've been looking for how to do that.

So the &1 means the piped value?

Great stuff!

Really loved the use of `rem`!

### What can you learn from this solution?

A huge amount can be learned from reading other people’s code. This is why we wanted to give exercism users the option of making their solutions public.

Here are some questions to help you reflect on this solution and learn the most from it.

• What compromises have been made?