ðŸŽ‰ Exercism Research is now launched. Help Exercism, help science and have some fun at research.exercism.io ðŸŽ‰

# jonathan-r's solution

## to Perfect Numbers in the Elixir Track

Published at Jul 13 2018 · 0 comments
Instructions
Test suite
Solution

#### Note:

This solution was written on an old version of Exercism. The tests below might not correspond to the solution code, and the exercise may have changed since this code was written.

Determine if a number is perfect, abundant, or deficient based on Nicomachus' (60 - 120 CE) classification scheme for natural numbers.

The Greek mathematician Nicomachus devised a classification scheme for natural numbers, identifying each as belonging uniquely to the categories of perfect, abundant, or deficient based on their aliquot sum. The aliquot sum is defined as the sum of the factors of a number not including the number itself. For example, the aliquot sum of 15 is (1 + 3 + 5) = 9

• Perfect: aliquot sum = number
• 6 is a perfect number because (1 + 2 + 3) = 6
• 28 is a perfect number because (1 + 2 + 4 + 7 + 14) = 28
• Abundant: aliquot sum > number
• 12 is an abundant number because (1 + 2 + 3 + 4 + 6) = 16
• 24 is an abundant number because (1 + 2 + 3 + 4 + 6 + 8 + 12) = 36
• Deficient: aliquot sum < number
• 8 is a deficient number because (1 + 2 + 4) = 7
• Prime numbers are deficient

Implement a way to determine whether a given number is perfect. Depending on your language track, you may also need to implement a way to determine whether a given number is abundant or deficient.

## Running tests

Execute the tests with:

``````\$ elixir perfect_numbers_test.exs
``````

### Pending tests

In the test suites, all but the first test have been skipped.

Once you get a test passing, you can unskip the next one by commenting out the relevant `@tag :pending` with a `#` symbol.

For example:

``````# @tag :pending
test "shouting" do
assert Bob.hey("WATCH OUT!") == "Whoa, chill out!"
end
``````

Or, you can enable all the tests by commenting out the `ExUnit.configure` line in the test suite.

``````# ExUnit.configure exclude: :pending, trace: true
``````

For more detailed information about the Elixir track, please see the help page.

## Source

Taken from Chapter 2 of Functional Thinking by Neal Ford. http://shop.oreilly.com/product/0636920029687.do

## Submitting Incomplete Solutions

It's possible to submit an incomplete solution so you can see how others have completed the exercise.

### perfect_numbers_test.exs

``````if !System.get_env("EXERCISM_TEST_EXAMPLES") do
end

ExUnit.start()
ExUnit.configure(exclude: :pending, trace: true)

defmodule PerfectNumbersTest do
use ExUnit.Case

describe "Perfect numbers" do
# @tag :pending
test "Smallest perfect number is classified correctly" do
assert PerfectNumbers.classify(6) == {:ok, :perfect}
end

@tag :pending
test "Medium perfect number is classified correctly" do
assert PerfectNumbers.classify(28) == {:ok, :perfect}
end

@tag :pending
test "Large perfect number is classified correctly" do
assert PerfectNumbers.classify(33_550_336) == {:ok, :perfect}
end
end

describe "Abundant numbers" do
@tag :pending
test "Smallest abundant number is classified correctly" do
assert PerfectNumbers.classify(12) == {:ok, :abundant}
end

@tag :pending
test "Medium abundant number is classified correctly" do
assert PerfectNumbers.classify(30) == {:ok, :abundant}
end

@tag :pending
test "Large abundant number is classified correctly" do
assert PerfectNumbers.classify(33_550_335) == {:ok, :abundant}
end
end

describe "Deficient numbers" do
@tag :pending
test "Smallest prime deficient number is classified correctly" do
assert PerfectNumbers.classify(2) == {:ok, :deficient}
end

@tag :pending
test "Smallest non-prime deficient number is classified correctly" do
assert PerfectNumbers.classify(4) == {:ok, :deficient}
end

@tag :pending
test "Medium deficient number is classified correctly" do
assert PerfectNumbers.classify(32) == {:ok, :deficient}
end

@tag :pending
test "Large deficient number is classified correctly" do
assert PerfectNumbers.classify(33_550_337) == {:ok, :deficient}
end

@tag :pending
test "Edge case (no factors other than itself) is classified correctly" do
assert PerfectNumbers.classify(1) == {:ok, :deficient}
end
end

describe "Invalid inputs" do
@tag :pending
test "Zero is rejected (not a natural number)" do
assert PerfectNumbers.classify(0) ==
{:error, "Classification is only possible for natural numbers."}
end

@tag :pending
test "Negative integer is rejected (not a natural number)" do
assert PerfectNumbers.classify(-1) ==
{:error, "Classification is only possible for natural numbers."}
end
end
end``````
``````defmodule PerfectNumbers do
@doc """
Determine the aliquot sum of the given `number`, by summing all the factors
of `number`, aside from `number` itself.

Based on this sum, classify the number as:

:perfect if the aliquot sum is equal to `number`
:abundant if the aliquot sum is greater than `number`
:deficient if the aliquot sum is less than `number`
"""
@spec classify(number :: integer) :: ({ :ok, atom } | { :error, String.t() })
def classify(number) when number <= 0,
do: {:error, "Classification is only possible for natural numbers."}
def classify(number) do
case aliquot_sum(number) do
^number               -> {:ok, :perfect}
sum when sum > number -> {:ok, :abundant}
sum when sum < number -> {:ok, :deficient}
end
end

@spec aliquot_sum(pos_integer) :: pos_integer
defp aliquot_sum(1),
do: 0
defp aliquot_sum(num),
do: num |> find_factors(2, [1]) |> Enum.uniq() |> Enum.sum()

@spec find_factors(pos_integer, pos_integer, [pos_integer]) :: [pos_integer]
defp find_factors(num, divisor, factors) when divisor * divisor > num,
do: factors
defp find_factors(num, divisor, factors) when rem(num, divisor) == 0,
do: find_factors(num, divisor + 1, [divisor, div(num, divisor) | factors])
defp find_factors(num, divisor, factors),
do: find_factors(num, divisor + 1, factors)
end``````

### What can you learn from this solution?

A huge amount can be learned from reading other peopleâ€™s code. This is why we wanted to give exercism users the option of making their solutions public.

Here are some questions to help you reflect on this solution and learn the most from it.

• What compromises have been made?