Avatar of davearonson

davearonson's solution

to OCR Numbers in the Elixir Track

Published at Aug 14 2019 · 0 comments
Instructions
Test suite
Solution

Given a 3 x 4 grid of pipes, underscores, and spaces, determine which number is represented, or whether it is garbled.

Step One

To begin with, convert a simple binary font to a string containing 0 or 1.

The binary font uses pipes and underscores, four rows high and three columns wide.

     _   #
    | |  # zero.
    |_|  #
         # the fourth row is always blank

Is converted to "0"

         #
      |  # one.
      |  #
         # (blank fourth row)

Is converted to "1"

If the input is the correct size, but not recognizable, your program should return '?'

If the input is the incorrect size, your program should return an error.

Step Two

Update your program to recognize multi-character binary strings, replacing garbled numbers with ?

Step Three

Update your program to recognize all numbers 0 through 9, both individually and as part of a larger string.

 _
 _|
|_

Is converted to "2"

      _  _     _  _  _  _  _  _  #
    | _| _||_||_ |_   ||_||_|| | # decimal numbers.
    ||_  _|  | _||_|  ||_| _||_| #
                                 # fourth line is always blank

Is converted to "1234567890"

Step Four

Update your program to handle multiple numbers, one per line. When converting several lines, join the lines with commas.

    _  _
  | _| _|
  ||_  _|

    _  _
|_||_ |_
  | _||_|

 _  _  _
  ||_||_|
  ||_| _|

Is converted to "123,456,789"

Running tests

Execute the tests with:

$ mix test

Pending tests

In the test suites, all but the first test have been skipped.

Once you get a test passing, you can unskip the next one by commenting out the relevant @tag :pending with a # symbol.

For example:

# @tag :pending
test "shouting" do
  assert Bob.hey("WATCH OUT!") == "Whoa, chill out!"
end

Or, you can enable all the tests by commenting out the ExUnit.configure line in the test suite.

# ExUnit.configure exclude: :pending, trace: true

If you're stuck on something, it may help to look at some of the available resources out there where answers might be found.

Source

Inspired by the Bank OCR kata http://codingdojo.org/cgi-bin/wiki.pl?KataBankOCR

Submitting Incomplete Solutions

It's possible to submit an incomplete solution so you can see how others have completed the exercise.

ocr_numbers_test.exs

defmodule OcrNumbersTest do
  use ExUnit.Case

  # @tag :pending
  test "Recognizes 0" do
    number =
      OcrNumbers.convert([
        " _ ",
        "| |",
        "|_|",
        "   "
      ])

    assert number == {:ok, "0"}
  end

  @tag :pending
  test "Recognizes 1" do
    number =
      OcrNumbers.convert([
        "   ",
        "  |",
        "  |",
        "   "
      ])

    assert number == {:ok, "1"}
  end

  @tag :pending
  test "Unreadable but correctly sized inputs return ?" do
    number =
      OcrNumbers.convert([
        "   ",
        "  _",
        "  |",
        "   "
      ])

    assert number == {:ok, "?"}
  end

  @tag :pending
  test "Input with a number of lines that is not a multiple of four raises an error" do
    number =
      OcrNumbers.convert([
        " _ ",
        "| |",
        "   "
      ])

    assert number == {:error, 'invalid line count'}
  end

  @tag :pending
  test "Input with a number of columns that is not a multiple of three raises an error" do
    number =
      OcrNumbers.convert([
        "    ",
        "   |",
        "   |",
        "    "
      ])

    assert number == {:error, 'invalid column count'}
  end

  @tag :pending
  test "Recognizes 110101100" do
    number =
      OcrNumbers.convert([
        "       _     _        _  _ ",
        "  |  || |  || |  |  || || |",
        "  |  ||_|  ||_|  |  ||_||_|",
        "                           "
      ])

    assert number == {:ok, "110101100"}
  end

  @tag :pending
  test "Garbled numbers in a string are replaced with ?" do
    number =
      OcrNumbers.convert([
        "       _     _           _ ",
        "  |  || |  || |     || || |",
        "  |  | _|  ||_|  |  ||_||_|",
        "                           "
      ])

    assert number == {:ok, "11?10?1?0"}
  end

  @tag :pending
  test "Recognizes 2" do
    number =
      OcrNumbers.convert([
        " _ ",
        " _|",
        "|_ ",
        "   "
      ])

    assert number == {:ok, "2"}
  end

  @tag :pending
  test "Recognizes 3" do
    number =
      OcrNumbers.convert([
        " _ ",
        " _|",
        " _|",
        "   "
      ])

    assert number == {:ok, "3"}
  end

  @tag :pending
  test "Recognizes 4" do
    number =
      OcrNumbers.convert([
        "   ",
        "|_|",
        "  |",
        "   "
      ])

    assert number == {:ok, "4"}
  end

  @tag :pending
  test "Recognizes 5" do
    number =
      OcrNumbers.convert([
        " _ ",
        "|_ ",
        " _|",
        "   "
      ])

    assert number == {:ok, "5"}
  end

  @tag :pending
  test "Recognizes 6" do
    number =
      OcrNumbers.convert([
        " _ ",
        "|_ ",
        "|_|",
        "   "
      ])

    assert number == {:ok, "6"}
  end

  @tag :pending
  test "Regonizes 7" do
    number =
      OcrNumbers.convert([
        " _ ",
        "  |",
        "  |",
        "   "
      ])

    assert number == {:ok, "7"}
  end

  @tag :pending
  test "Recognizes 8" do
    number =
      OcrNumbers.convert([
        " _ ",
        "|_|",
        "|_|",
        "   "
      ])

    assert number == {:ok, "8"}
  end

  @tag :pending
  test "Recognizes 9" do
    number =
      OcrNumbers.convert([
        " _ ",
        "|_|",
        " _|",
        "   "
      ])

    assert number == {:ok, "9"}
  end

  @tag :pending
  test "Recognizes string of decimal numbers" do
    number =
      OcrNumbers.convert([
        "    _  _     _  _  _  _  _  _ ",
        "  | _| _||_||_ |_   ||_||_|| |",
        "  ||_  _|  | _||_|  ||_| _||_|",
        "                              "
      ])

    assert number == {:ok, "1234567890"}
  end

  @tag :pending
  test "Numbers separated by empty lines are recognized. Lines are joined by commas." do
    number =
      OcrNumbers.convert([
        "    _  _ ",
        "  | _| _|",
        "  ||_  _|",
        "         ",
        "    _  _ ",
        "|_||_ |_ ",
        "  | _||_|",
        "         ",
        " _  _  _ ",
        "  ||_||_|",
        "  ||_| _|",
        "         "
      ])

    assert number == {:ok, "123,456,789"}
  end
end

test_helper.exs

ExUnit.start()
ExUnit.configure(exclude: :pending, trace: true)
defmodule OcrNumbers do
  @doc """
  Given a 3 x 4 grid of pipes, underscores, and spaces, determine which number is represented, or
  whether it is garbled.
  """

  @conversions %{
    " _ | ||_|   " => "0",
    "     |  |   " => "1",
    " _  _||_    " => "2",
    " _  _| _|   " => "3",
    "   |_|  |   " => "4",
    " _ |_  _|   " => "5",
    " _ |_ |_|   " => "6",
    " _   |  |   " => "7",
    " _ |_||_|   " => "8",
    " _ |_| _|   " => "9"
  }

  @spec convert([String.t()]) :: String.t()
  def convert(input) do
    with {:ok, _}         <- check_matrix_height(input),
         rows             <- Enum.chunk_every(input, 4),
         {:ok, converted} <- convert_rows(rows, [])
    do
      {:ok, Enum.join(converted, ",")}
    else
      err -> err
    end
  end

  defp check_matrix_height(input) do
    case rem(length(input), 4) do
      0 -> {:ok, nil}
      _ -> {:error, 'invalid line count'}
    end
  end

  defp convert_rows([]          , acc), do: {:ok, Enum.reverse(acc)}
  defp convert_rows([first|rest], acc)  do
    with {:ok, result} <- convert_row(first) do
      convert_rows(rest, [result|acc])
    else
      err -> err
    end
  end

  defp convert_row(input) do
    if check_matrix_width(input) do
      result =
        input
        |> Enum.map(&String.graphemes/1)
        |> ocr_digits([])
        |> Enum.join
      {:ok, result}
    else
      {:error, 'invalid column count'} 
    end
  end

  defp check_matrix_width([top_line|rest]) do
    len = String.length(top_line)
    rem(len, 3) == 0 and Enum.all?(rest, &(String.length(&1) == len))
  end

  defp ocr_digits([[],[],[],[]], acc), do: Enum.reverse(acc)
  defp ocr_digits(input        , acc)  do
    this_digit = Enum.map(input, &(Enum.take(&1, 3)))
    rest       = Enum.map(input, &(Enum.drop(&1, 3)))
    converted  = @conversions[Enum.join(this_digit)] || "?"
    ocr_digits(rest, [converted|acc])
  end

end

Community comments

Find this solution interesting? Ask the author a question to learn more.

What can you learn from this solution?

A huge amount can be learned from reading other people’s code. This is why we wanted to give exercism users the option of making their solutions public.

Here are some questions to help you reflect on this solution and learn the most from it.

  • What compromises have been made?
  • Are there new concepts here that you could read more about to improve your understanding?