# Greycoat21's solution

## to Space Age in the Delphi Pascal Track

Published at Feb 27 2019 · 0 comments
Instructions
Test suite
Solution

Given an age in seconds, calculate how old someone would be on:

• Earth: orbital period 365.25 Earth days, or 31557600 seconds
• Mercury: orbital period 0.2408467 Earth years
• Venus: orbital period 0.61519726 Earth years
• Mars: orbital period 1.8808158 Earth years
• Jupiter: orbital period 11.862615 Earth years
• Saturn: orbital period 29.447498 Earth years
• Uranus: orbital period 84.016846 Earth years
• Neptune: orbital period 164.79132 Earth years

So if you were told someone were 1,000,000,000 seconds old, you should be able to say that they're 31.69 Earth-years old.

If you're wondering why Pluto didn't make the cut, go watch this youtube video.

## Testing

In order to run the tests for this track, you will need to install DUnitX. Please see the installation instructions for more information.

If Delphi is properly installed, and `*.dpr` file types have been associated with Delphi, then double clicking the supplied `*.dpr` file will start Delphi and load the exercise/project. `control + F9` is the keyboard shortcut to compile the project or pressing `F9` will compile and run the project.

Alternatively you may opt to start Delphi and load your project via. the `File` drop down menu.

### When Questions Come Up

We monitor the Pascal-Delphi support room on gitter.im to help you with any questions that might arise.

### Submitting Exercises

Note that, when trying to submit an exercise, make sure the exercise file you're submitting is in the `exercism/delphi/<exerciseName>` directory.

For example, if you're submitting `ubob.pas` for the Bob exercise, the submit command would be something like `exercism submit <path_to_exercism_dir>/delphi/bob/ubob.pas`.

## Source

Partially inspired by Chapter 1 in Chris Pine's online Learn to Program tutorial. http://pine.fm/LearnToProgram/?Chapter=01

## Submitting Incomplete Solutions

It's possible to submit an incomplete solution so you may receive assistance from a mentor.

### uSpaceAgeTests.pas

``````unit uSpaceAgeTests;

interface
uses
DUnitX.TestFramework;

const
CanonicalVersion = '1.2.0';

type

[TestFixture]
SpaceAgeTests = class(TObject)
public
[Test]
//    [Ignore('Comment the "[Ignore]" statement to run the test')]
procedure Age_on_earth;

[Test]
[Ignore]
procedure Age_on_mercury;

[Test]
[Ignore]
procedure Age_on_venus;

[Test]
[Ignore]
procedure Age_on_mars;

[Test]
[Ignore]
procedure Age_on_jupiter;

[Test]
[Ignore]
procedure Age_on_saturn;

[Test]
[Ignore]
procedure Age_on_uranus;

[Test]
[Ignore]
procedure Age_on_neptune;
end;

implementation
uses uSpaceAge;

{ SpaceAgeTests }

procedure SpaceAgeTests.Age_on_earth;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(1000000000);
expectedAge := 31.69;
Assert.AreEqual(expectedAge, MyAge.OnEarth);
end;

procedure SpaceAgeTests.Age_on_jupiter;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(901876382);
expectedAge := 2.41;
Assert.AreEqual(expectedAge, MyAge.OnJupiter);
end;

procedure SpaceAgeTests.Age_on_mars;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(2129871239);
expectedAge := 35.88;
Assert.AreEqual(expectedAge, MyAge.OnMars);
end;

procedure SpaceAgeTests.Age_on_mercury;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(2134835688);
expectedAge := 280.88;
Assert.AreEqual(expectedAge, MyAge.OnMercury);
end;

procedure SpaceAgeTests.Age_on_neptune;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(1821023456);
expectedAge := 0.35;
Assert.AreEqual(expectedAge, MyAge.OnNeptune);
end;

procedure SpaceAgeTests.Age_on_saturn;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(2000000000);
expectedAge := 2.15;
Assert.AreEqual(expectedAge, MyAge.OnSaturn);
end;

procedure SpaceAgeTests.Age_on_uranus;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(1210123456);
expectedAge := 0.46;
Assert.AreEqual(expectedAge, MyAge.OnUranus);
end;

procedure SpaceAgeTests.Age_on_venus;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(189839836);
expectedAge := 9.78;
Assert.AreEqual(expectedAge, MyAge.OnVenus);
end;

initialization
TDUnitX.RegisterTestFixture(SpaceAgeTests);
end.``````
``````unit uSpaceAge;

interface

type
ISpaceAge = interface
function OnEarth:   Double;
function OnMercury: Double;
function OnVenus:   Double;
function OnMars:    Double;
function OnJupiter: Double;
function OnSaturn:  Double;
function OnUranus:  Double;
function OnNeptune: Double;
end;

function NewSpaceAge(Seconds: Integer): ISpaceAge;

implementation

uses
Math;

type
TSpaceAge = class(TInterfacedObject, ISpaceAge)
private
FAgeInSeconds: Integer;

type
// In order from the sun
TPlanetIndex =
(piMercury,
piVenus,
piEarth,
piMars,
piJupiter,
piSaturn,
piUranus,
piNeptune);

const EarthYearInSeconds   = 31557600;
const MercuryYearInSeconds = EarthYearInSeconds *   0.2408467;
const VenusYearInSeconds   = EarthYearInSeconds *   0.61519726;
const MarsYearInSeconds    = EarthYearInSeconds *   1.8808158;
const JupiterYearInSeconds = EarthYearInSeconds *  11.862615;
const SaturnYearInSeconds  = EarthYearInSeconds *  29.447498;
const UranusYearInSeconds  = EarthYearInSeconds *  84.016846;
const NeptuneYearInSeconds = EarthYearInSeconds * 164.79132;

const PlanetYearInSeconds: array [piMercury..piNeptune] of Double = (
MercuryYearInSeconds,
VenusYearInSeconds,
EarthYearInSeconds,
MarsYearInSeconds,
JupiterYearInSeconds,
SaturnYearInSeconds,
UranusYearInSeconds,
NeptuneYearInSeconds);

function AgeOnPlanet(PlanetIndex: TPlanetIndex): Double;
public
constructor Create(AgeInSeconds: Integer);
// Reports age in years
function OnEarth:   Double;
function OnMercury: Double;
function OnVenus:   Double;
function OnMars:    Double;
function OnJupiter: Double;
function OnSaturn:  Double;
function OnUranus:  Double;
function OnNeptune: Double;
end;

function NewSpaceAge(Seconds: Integer): ISpaceAge;
begin
Result := TSpaceAge.Create(Seconds);
end;

{ TSpaceAge }

constructor TSpaceAge.Create(AgeInSeconds: Integer);
begin
FAgeInSeconds := AgeInSeconds;
end;

function TSpaceAge.AgeOnPlanet(PlanetIndex: TPlanetIndex): Double;
begin
Result := RoundTo(FAgeInSeconds / PlanetYearInSeconds[PlanetIndex], -2);
end;

function TSpaceAge.OnEarth: Double;
begin
Result := AgeOnPlanet(piEarth);
end;

function TSpaceAge.OnJupiter: Double;
begin
Result := AgeOnPlanet(piJupiter);
end;

function TSpaceAge.OnMars: Double;
begin
Result := AgeOnPlanet(piMars);
end;

function TSpaceAge.OnMercury: Double;
begin
Result := AgeOnPlanet(piMercury);
end;

function TSpaceAge.OnNeptune: Double;
begin
Result := AgeOnPlanet(piNeptune);
end;

function TSpaceAge.OnSaturn: Double;
begin
Result := AgeOnPlanet(piSaturn);
end;

function TSpaceAge.OnUranus: Double;
begin
Result := AgeOnPlanet(piUranus);
end;

function TSpaceAge.OnVenus: Double;
begin
Result := AgeOnPlanet(piVenus);
end;

end.``````