Exercism v3 launches on Sept 1st 2021. Learn more! ๐๐๐

rpottsoh's solution

to Space Age in the Delphi Pascal Track

Published at Jan 25 2019 · 0 comments
Instructions
Test suite
Solution

Given an age in seconds, calculate how old someone would be on:

• Earth: orbital period 365.25 Earth days, or 31557600 seconds
• Mercury: orbital period 0.2408467 Earth years
• Venus: orbital period 0.61519726 Earth years
• Mars: orbital period 1.8808158 Earth years
• Jupiter: orbital period 11.862615 Earth years
• Saturn: orbital period 29.447498 Earth years
• Uranus: orbital period 84.016846 Earth years
• Neptune: orbital period 164.79132 Earth years

So if you were told someone were 1,000,000,000 seconds old, you should be able to say that they're 31.69 Earth-years old.

If you're wondering why Pluto didn't make the cut, go watch this youtube video.

Testing

In order to run the tests for this track, you will need to install DUnitX. Please see the installation instructions for more information.

Loading Exercises into Delphi

If Delphi is properly installed, and `*.dpr` file types have been associated with Delphi, then double clicking the supplied `*.dpr` file will start Delphi and load the exercise/project. `control + F9` is the keyboard shortcut to compile the project or pressing `F9` will compile and run the project.

Alternatively you may opt to start Delphi and load your project via. the `File` drop down menu.

When Questions Come Up

We monitor the Pascal-Delphi support room on gitter.im to help you with any questions that might arise.

Submitting Exercises

Note that, when trying to submit an exercise, make sure the exercise file you're submitting is in the `exercism/delphi/<exerciseName>` directory.

For example, if you're submitting `ubob.pas` for the Bob exercise, the submit command would be something like `exercism submit <path_to_exercism_dir>/delphi/bob/ubob.pas`.

Source

Partially inspired by Chapter 1 in Chris Pine's online Learn to Program tutorial. http://pine.fm/LearnToProgram/?Chapter=01

Submitting Incomplete Solutions

It's possible to submit an incomplete solution so you may receive assistance from a mentor.

uSpaceAgeTests.pas

``````unit uSpaceAgeTests;

interface
uses
DUnitX.TestFramework;

const
CanonicalVersion = '1.2.0';

type

[TestFixture]
SpaceAgeTests = class(TObject)
public
[Test]
//    [Ignore('Comment the "[Ignore]" statement to run the test')]
procedure Age_on_earth;

[Test]
[Ignore]
procedure Age_on_mercury;

[Test]
[Ignore]
procedure Age_on_venus;

[Test]
[Ignore]
procedure Age_on_mars;

[Test]
[Ignore]
procedure Age_on_jupiter;

[Test]
[Ignore]
procedure Age_on_saturn;

[Test]
[Ignore]
procedure Age_on_uranus;

[Test]
[Ignore]
procedure Age_on_neptune;
end;

implementation
uses uSpaceAge;

{ SpaceAgeTests }

procedure SpaceAgeTests.Age_on_earth;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(1000000000);
expectedAge := 31.69;
Assert.AreEqual(expectedAge, MyAge.OnEarth);
end;

procedure SpaceAgeTests.Age_on_jupiter;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(901876382);
expectedAge := 2.41;
Assert.AreEqual(expectedAge, MyAge.OnJupiter);
end;

procedure SpaceAgeTests.Age_on_mars;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(2129871239);
expectedAge := 35.88;
Assert.AreEqual(expectedAge, MyAge.OnMars);
end;

procedure SpaceAgeTests.Age_on_mercury;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(2134835688);
expectedAge := 280.88;
Assert.AreEqual(expectedAge, MyAge.OnMercury);
end;

procedure SpaceAgeTests.Age_on_neptune;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(1821023456);
expectedAge := 0.35;
Assert.AreEqual(expectedAge, MyAge.OnNeptune);
end;

procedure SpaceAgeTests.Age_on_saturn;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(2000000000);
expectedAge := 2.15;
Assert.AreEqual(expectedAge, MyAge.OnSaturn);
end;

procedure SpaceAgeTests.Age_on_uranus;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(1210123456);
expectedAge := 0.46;
Assert.AreEqual(expectedAge, MyAge.OnUranus);
end;

procedure SpaceAgeTests.Age_on_venus;
var
MyAge: ISpaceAge;
expectedAge: double;
begin
MyAge := NewSpaceAge(189839836);
expectedAge := 9.78;
Assert.AreEqual(expectedAge, MyAge.OnVenus);
end;

initialization
TDUnitX.RegisterTestFixture(SpaceAgeTests);
end.``````
``````unit uSpaceAge;

interface

type
ISpaceAge = interface(IInvokable)
['{D2226242-6BFC-4C80-A9EB-D5A67FA406FE}']
function OnEarth: double;
function OnMercury: double;
function OnVenus: double;
function OnMars: double;
function OnJupiter: double;
function OnSaturn: double;
function OnUranus: double;
function OnNeptune: double;
end;

function NewSpaceAge(Seconds: Integer): ISpaceAge;

implementation
uses System.Generics.Collections, System.Math;

{ TSpaceAge }
type
TSpaceAge = class(TInterfacedObject, ISpaceAge)
private
const
cEarth_Orbit_In_Seconds = 31557600;
type
TPlanets = (Earth, Mercury, Venus, Mars, Jupiter, Saturn, Uranus, Neptune);
var
earthYearToPlanetPeriod: TDictionary<TPlanets, double>;
fSeconds: Integer;
function CalculateAge(periodInEarthYears: double): double;
constructor Create(Seconds: Integer);
destructor Destroy; override;
function OnEarth: double;
function OnMercury: double;
function OnVenus: double;
function OnMars: double;
function OnJupiter: double;
function OnSaturn: double;
function OnUranus: double;
function OnNeptune: double;
end;

function NewSpaceAge(Seconds: Integer): ISpaceAge;
begin
result := TSpaceAge.Create(Seconds);
end;

function TSpaceAge.CalculateAge(periodInEarthYears: double): double;
begin
result := SimpleRoundTo(fSeconds / (cEarth_Orbit_In_Seconds * periodInEarthYears), -2);
end;

constructor TSpaceAge.Create(Seconds: Integer);
begin
fSeconds := Seconds;
earthYearToPlanetPeriod := TDictionary<TPlanets, double>.Create;
with earthYearToPlanetPeriod do
begin
add(Earth, 1.0);
add(Mercury, 0.2408467);
add(Venus, 0.61519726);
add(Mars, 1.8808158);
add(Jupiter, 11.862615);
add(Saturn, 29.447498);
add(Uranus, 84.016846);
add(Neptune, 164.79132);
end;
end;

destructor TSpaceAge.Destroy;
begin
earthYearToPlanetPeriod.DisposeOf;
inherited;
end;

function TSpaceAge.OnEarth: double;
begin
result := CalculateAge(earthYearToPlanetPeriod[Earth]);
end;

function TSpaceAge.OnJupiter: double;
begin
result := CalculateAge(earthYearToPlanetPeriod[Jupiter]);
end;

function TSpaceAge.OnMars: double;
begin
result := CalculateAge(earthYearToPlanetPeriod[Mars]);
end;

function TSpaceAge.OnMercury: double;
begin
result := CalculateAge(earthYearToPlanetPeriod[Mercury]);
end;

function TSpaceAge.OnNeptune: double;
begin
result := CalculateAge(earthYearToPlanetPeriod[Neptune]);
end;

function TSpaceAge.OnSaturn: double;
begin
result := CalculateAge(earthYearToPlanetPeriod[Saturn]);
end;

function TSpaceAge.OnUranus: double;
begin
result := CalculateAge(earthYearToPlanetPeriod[Uranus]);
end;

function TSpaceAge.OnVenus: double;
begin
result := CalculateAge(earthYearToPlanetPeriod[Venus]);
end;

end.``````

Community comments

Find this solution interesting? Ask the author a question to learn more.

What can you learn from this solution?

A huge amount can be learned from reading other peopleโs code. This is why we wanted to give exercism users the option of making their solutions public.

Here are some questions to help you reflect on this solution and learn the most from it.

• What compromises have been made?
• Are there new concepts here that you could read more about to improve your understanding?