🎉 Exercism Research is now launched. Help Exercism, help science and have some fun at research.exercism.io 🎉
Avatar of Selticq

Selticq's solution

to Space Age in the Delphi Pascal Track

Published at Feb 15 2021 · 0 comments
Instructions
Test suite
Solution

Given an age in seconds, calculate how old someone would be on:

  • Mercury: orbital period 0.2408467 Earth years
  • Venus: orbital period 0.61519726 Earth years
  • Earth: orbital period 1.0 Earth years, 365.25 Earth days, or 31557600 seconds
  • Mars: orbital period 1.8808158 Earth years
  • Jupiter: orbital period 11.862615 Earth years
  • Saturn: orbital period 29.447498 Earth years
  • Uranus: orbital period 84.016846 Earth years
  • Neptune: orbital period 164.79132 Earth years

So if you were told someone were 1,000,000,000 seconds old, you should be able to say that they're 31.69 Earth-years old.

If you're wondering why Pluto didn't make the cut, go watch this youtube video.

Testing

In order to run the tests for this track, you will need to install DUnitX. Please see the installation instructions for more information.

Loading Exercises into Delphi

If Delphi is properly installed, and *.dpr file types have been associated with Delphi, then double clicking the supplied *.dpr file will start Delphi and load the exercise/project. control + F9 is the keyboard shortcut to compile the project or pressing F9 will compile and run the project.

Alternatively you may opt to start Delphi and load your project via. the File drop down menu.

When Questions Come Up

We monitor the Pascal-Delphi support room on gitter.im to help you with any questions that might arise.

Submitting Exercises

Note that, when trying to submit an exercise, make sure the exercise file you're submitting is in the exercism/delphi/<exerciseName> directory.

For example, if you're submitting ubob.pas for the Bob exercise, the submit command would be something like exercism submit <path_to_exercism_dir>/delphi/bob/ubob.pas.

Source

Partially inspired by Chapter 1 in Chris Pine's online Learn to Program tutorial. http://pine.fm/LearnToProgram/?Chapter=01

Submitting Incomplete Solutions

It's possible to submit an incomplete solution so you may request help from a mentor.

uSpaceAgeTests.pas

unit uSpaceAgeTests;

interface
uses
  DUnitX.TestFramework;

const
  CanonicalVersion = '1.2.0';

type

  [TestFixture]
  SpaceAgeTests = class(TObject)
  public
    [Test]
//    [Ignore('Comment the "[Ignore]" statement to run the test')]
    procedure Age_on_earth;

    [Test]
    [Ignore]
    procedure Age_on_mercury;

    [Test]
    [Ignore]
    procedure Age_on_venus;

    [Test]
    [Ignore]
    procedure Age_on_mars;

    [Test]
    [Ignore]
    procedure Age_on_jupiter;

    [Test]
    [Ignore]
    procedure Age_on_saturn;

    [Test]
    [Ignore]
    procedure Age_on_uranus;

    [Test]
    [Ignore]
    procedure Age_on_neptune;
  end;

implementation
uses uSpaceAge;

{ SpaceAgeTests }

procedure SpaceAgeTests.Age_on_earth;
var
  MyAge: ISpaceAge;
  expectedAge: double;
begin
  MyAge := NewSpaceAge(1000000000);
  expectedAge := 31.69;
  Assert.AreEqual(expectedAge, MyAge.OnEarth);
end;

procedure SpaceAgeTests.Age_on_jupiter;
var
  MyAge: ISpaceAge;
  expectedAge: double;
begin
  MyAge := NewSpaceAge(901876382);
  expectedAge := 2.41;
  Assert.AreEqual(expectedAge, MyAge.OnJupiter);
end;

procedure SpaceAgeTests.Age_on_mars;
var
  MyAge: ISpaceAge;
  expectedAge: double;
begin
  MyAge := NewSpaceAge(2129871239);
  expectedAge := 35.88;
  Assert.AreEqual(expectedAge, MyAge.OnMars);
end;

procedure SpaceAgeTests.Age_on_mercury;
var
  MyAge: ISpaceAge;
  expectedAge: double;
begin
  MyAge := NewSpaceAge(2134835688);
  expectedAge := 280.88;
  Assert.AreEqual(expectedAge, MyAge.OnMercury);
end;

procedure SpaceAgeTests.Age_on_neptune;
var
  MyAge: ISpaceAge;
  expectedAge: double;
begin
  MyAge := NewSpaceAge(1821023456);
  expectedAge := 0.35;
  Assert.AreEqual(expectedAge, MyAge.OnNeptune);
end;

procedure SpaceAgeTests.Age_on_saturn;
var
  MyAge: ISpaceAge;
  expectedAge: double;
begin
  MyAge := NewSpaceAge(2000000000);
  expectedAge := 2.15;
  Assert.AreEqual(expectedAge, MyAge.OnSaturn);
end;

procedure SpaceAgeTests.Age_on_uranus;
var
  MyAge: ISpaceAge;
  expectedAge: double;
begin
  MyAge := NewSpaceAge(1210123456);
  expectedAge := 0.46;
  Assert.AreEqual(expectedAge, MyAge.OnUranus);
end;

procedure SpaceAgeTests.Age_on_venus;
var
  MyAge: ISpaceAge;
  expectedAge: double;
begin
  MyAge := NewSpaceAge(189839836);
  expectedAge := 9.78;
  Assert.AreEqual(expectedAge, MyAge.OnVenus);
end;

initialization
  TDUnitX.RegisterTestFixture(SpaceAgeTests);
end.
unit uSpaceAge;

interface

type
  ISpaceAge = interface
  ['{D74DACFB-1D24-4540-9531-193EC955FDFB}']
    function OnEarth(): double;
    function OnJupiter(): double;
    function OnMars(): double;
    function OnMercury(): double;
    function OnNeptune(): double;
    function OnSaturn(): double;
    function OnUranus(): double;
    function OnVenus(): double;
  end;

  TSpaceAge = class(TInterfacedObject, ISpaceAge)
    private
      var
        FAgeInSeconds: integer;
      const
        EarthOrbitalPeriodInSecond = 31557600;
        MercuryOrbitalPeriodInEarthYears = 0.2408467;
        VenusOrbitalPeriodInEarthYears = 0.61519726;
        MarsOrbitalPeriodInEarthYears = 1.8808158;
        JupiterOrbitalPeriodInEarthYears = 11.862615;
        SaturnOrbitalPeriodInEarthYears = 29.447498;
        UranusOrbitalPeriodInEarthYears = 84.016846;
        NeptuneOrbitalPeriodInEarthYears = 164.79132;
      function GetAgeOnEarth(): double;
      function RoundAge(OrbitalPeriodFactor: double): double;
    public
      constructor Create(AAge: Integer);
      function OnEarth(): double;
      function OnMercury(): double;
      function OnVenus(): double;
      function OnMars(): double;
      function OnJupiter(): double;
      function OnSaturn(): double;
      function OnUranus(): double;
      function OnNeptune(): double;
  end;

function NewSpaceAge(AAge: Integer): TSpaceAge;

implementation

uses
  System.Math;

function NewSpaceAge(AAge: Integer): TSpaceAge;
begin
  result := TSpaceAge.Create(AAge);
end;

constructor TSpaceAge.Create(AAge: Integer);
begin
  FAgeInSeconds := AAge;
end;

function TSpaceAge.GetAgeOnEarth(): Double;
begin
  result := FAgeInSeconds / self.EarthOrbitalPeriodInSecond;
end;

function TSpaceAge.RoundAge(OrbitalPeriodFactor: double) : double;
begin
  result := RoundTo(GetAgeOnEarth / OrbitalPeriodFactor, -2);
end;

function TSpaceAge.OnEarth(): double;
begin
  result := RoundAge(1);
end;

function TSpaceAge.OnMercury(): double;
begin
  result := RoundAge(MercuryOrbitalPeriodInEarthYears);
end;

function TSpaceAge.OnVenus(): double;
begin
  result := RoundAge(VenusOrbitalPeriodInEarthYears);
end;

function TSpaceAge.OnMars(): Double;
begin
  result := RoundAge(MarsOrbitalPeriodInEarthYears);
end;

function TSpaceAge.OnJupiter(): double;
begin
  result := RoundAge(JupiterOrbitalPeriodInEarthYears);
end;

function TSpaceAge.OnSaturn(): double;
begin
  result := RoundAge(SaturnOrbitalPeriodInEarthYears);
end;

function TSpaceAge.OnUranus(): double;
begin
  result := RoundAge(UranusOrbitalPeriodInEarthYears);
end;

function TSpaceAge.OnNeptune(): double;
begin
  result := RoundAge(NeptuneOrbitalPeriodInEarthYears);
end;


end.

Community comments

Find this solution interesting? Ask the author a question to learn more.

What can you learn from this solution?

A huge amount can be learned from reading other people’s code. This is why we wanted to give exercism users the option of making their solutions public.

Here are some questions to help you reflect on this solution and learn the most from it.

  • What compromises have been made?
  • Are there new concepts here that you could read more about to improve your understanding?