Exercism v3 launches on Sept 1st 2021. Learn more! ๐Ÿš€๐Ÿš€๐Ÿš€
Avatar of eferim

eferim's solution

to Saddle Points in the Delphi Pascal Track

Published at Sep 02 2018 · 0 comments
Instructions
Test suite
Solution

Note:

This exercise has changed since this solution was written.

Detect saddle points in a matrix.

So say you have a matrix like so:

    0  1  2
  |---------
0 | 9  8  7
1 | 5  3  2     <--- saddle point at (1,0)
2 | 6  6  7

It has a saddle point at (1, 0).

It's called a "saddle point" because it is greater than or equal to every element in its row and less than or equal to every element in its column.

A matrix may have zero or more saddle points.

Your code should be able to provide the (possibly empty) list of all the saddle points for any given matrix.

The matrix can have a different number of rows and columns (Non square).

Note that you may find other definitions of matrix saddle points online, but the tests for this exercise follow the above unambiguous definition.

Testing

In order to run the tests for this track, you will need to install DUnitX. Please see the installation instructions for more information.

Loading Exercises into Delphi

If Delphi is properly installed, and *.dpr file types have been associated with Delphi, then double clicking the supplied *.dpr file will start Delphi and load the exercise/project. control + F9 is the keyboard shortcut to compile the project or pressing F9 will compile and run the project.

Alternatively you may opt to start Delphi and load your project via. the File drop down menu.

When Questions Come Up

We monitor the Pascal-Delphi support room on gitter.im to help you with any questions that might arise.

Submitting Exercises

Note that, when trying to submit an exercise, make sure the exercise file you're submitting is in the exercism/delphi/<exerciseName> directory.

For example, if you're submitting ubob.pas for the Bob exercise, the submit command would be something like exercism submit <path_to_exercism_dir>/delphi/bob/ubob.pas.

Source

J Dalbey's Programming Practice problems http://users.csc.calpoly.edu/~jdalbey/103/Projects/ProgrammingPractice.html

Submitting Incomplete Solutions

It's possible to submit an incomplete solution so you may receive assistance from a mentor.

uSaddlePointsTests.pas

//******************************************************************
// Hint: You will be using TTuple in your solution.  TTuple is
// declared in this unit.  It will be necessary for you to add
// a uses statement in the interface section of uSaddlePoints.pas.
//******************************************************************

unit uSaddlePointsTests;

interface
uses
  DUnitX.TestFramework;

const
  CanonicalVersion = '1.3.0';

type

  [TestFixture]
  TSaddlePointTests = class(TObject)
  public
    [Test]
//    [Ignore('Comment the "[Ignore]" statement to run the test')]
    procedure Can_identify_single_saddle_point;

    [Test]
    [Ignore]
    procedure Can_identify_that_empty_matrix_has_no_saddle_points;

    [Test]
    [Ignore]
    procedure Can_identify_lack_of_saddle_points_when_there_are_none;

    [Test]
    [Ignore]
    procedure Can_identify_multiple_saddle_points_in_a_column;

    [Test]
    [Ignore]
    procedure Can_identify_multiple_saddle_points_in_a_row;

    [Test]
    [Ignore]
    procedure Can_identify_saddle_point_in_bottom_right_corner;

    [Test]
    [Ignore]
    procedure Can_identify_saddle_points_in_a_non_square_matrix;

    [Test]
    [Ignore]
    procedure Can_identify_that_saddle_points_in_a_single_column_matrix_are_those_with_the_minimum_value;

    [Test]
    [Ignore]
    procedure Can_identify_that_saddle_points_in_a_single_row_matrix_are_those_with_the_maximum_value;
  end;

  TTuple<T1, T2> = record
  private
    fValue1: T1;
    fValue2: T2;
  public
    constructor Create(Value1: T1; Value2: T2);
    property Value1 : T1 read fValue1;
    property Value2 : T2 read fValue2;
  end;

implementation
uses uSaddlePoints;

constructor TTuple<T1, T2>.Create(Value1: T1; Value2: T2);
begin
  fValue1 := Value1;
  fValue2 := Value2;
end;

procedure TSaddlePointTests.Can_identify_single_saddle_point;
const
  rows = 3;
  columns = 3;
var
  SaddlePoints: ISaddlePoints;
  values: TArray<TArray<integer>>;
  expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, rows, columns);
  values[0,0] := 9; values[0,1] := 8; values[0,2] := 7;
  values[1,0] := 5; values[1,1] := 3; values[1,2] := 2;
  values[2,0] := 6; values[2,1] := 6; values[2,2] := 7;

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 1);
  expected[0] := TTuple<integer,integer>.Create(1,0);
  Assert.AreEqual(expected, SaddlePoints.Calculate);
end;

procedure TSaddlePointTests.Can_identify_that_empty_matrix_has_no_saddle_points;
const
  rows = 0;
  columns = 0;
var
  SaddlePoints: ISaddlePoints;
  values: TArray<TArray<integer>>;
  expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, rows, columns);

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 0);
  Assert.AreEqual(expected, SaddlePoints.Calculate);
end;

procedure TSaddlePointTests.Can_identify_that_saddle_points_in_a_single_column_matrix_are_those_with_the_minimum_value;
const
  rows = 4;
  columns = 1;
var
  SaddlePoints: ISaddlePoints;
  values: TArray<TArray<integer>>;
  expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, rows, columns);
  values[0,0] := 2;
  values[1,0] := 1;
  values[2,0] := 4;
  values[3,0] := 1;

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 2);
  expected[0] := TTuple<integer,integer>.Create(1,0);
  expected[1] := TTuple<integer,integer>.Create(3,0);
  Assert.AreEqual(expected, SaddlePoints.Calculate);
end;

procedure TSaddlePointTests.Can_identify_that_saddle_points_in_a_single_row_matrix_are_those_with_the_maximum_value;
const
  rows = 1;
  columns = 4;
var
  SaddlePoints: ISaddlePoints;
  values: TArray<TArray<integer>>;
  expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, rows, columns);
  values[0,0] := 2; values[0,1] := 5; values[0,2] := 3; values[0,3] := 5;

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 2);
  expected[0] := TTuple<integer,integer>.Create(0,1);
  expected[1] := TTuple<integer,integer>.Create(0,3);
  Assert.AreEqual(expected, SaddlePoints.Calculate);
end;

procedure TSaddlePointTests.Can_identify_lack_of_saddle_points_when_there_are_none;
const
  rows = 3;
  columns = 3;
var
  SaddlePoints: ISaddlePoints;
  values: TArray<TArray<integer>>;
  expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, rows, columns);
  values[0,0] := 1; values[0,1] := 2; values[0,2] := 3;
  values[1,0] := 3; values[1,1] := 1; values[1,2] := 2;
  values[2,0] := 2; values[2,1] := 3; values[2,2] := 1;

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 0);
  Assert.AreEqual(expected, SaddlePoints.Calculate);
end;

procedure TSaddlePointTests.Can_identify_multiple_saddle_points_in_a_column;
const
  rows = 3;
  columns = 3;
var
  SaddlePoints: ISaddlePoints;
  values: TArray<TArray<integer>>;
  expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, rows, columns);
  values[0,0] := 4; values[0,1] := 5; values[0,2] := 4;
  values[1,0] := 3; values[1,1] := 5; values[1,2] := 5;
  values[2,0] := 1; values[2,1] := 5; values[2,2] := 4;

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 3);
  expected[0] := TTuple<integer,integer>.Create(0,1);
  expected[1] := TTuple<integer,integer>.Create(1,1);
  expected[2] := TTuple<integer,integer>.Create(2,1);
  Assert.AreEqual(expected, SaddlePoints.Calculate);
end;

procedure TSaddlePointTests.Can_identify_multiple_saddle_points_in_a_row;
const
  rows = 3;
  columns = 3;
var
  SaddlePoints: ISaddlePoints;
  values: TArray<TArray<integer>>;
  expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, rows, columns);
  values[0,0] := 6; values[0,1] := 7; values[0,2] := 8;
  values[1,0] := 5; values[1,1] := 5; values[1,2] := 5;
  values[2,0] := 7; values[2,1] := 5; values[2,2] := 6;

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 3);
  expected[0] := TTuple<integer,integer>.Create(1,0);
  expected[1] := TTuple<integer,integer>.Create(1,1);
  expected[2] := TTuple<integer,integer>.Create(1,2);
  Assert.AreEqual(expected, SaddlePoints.Calculate);
end;

procedure TSaddlePointTests.Can_identify_saddle_points_in_a_non_square_matrix;
const
  rows = 2;
  columns = 3;
var
  SaddlePoints: ISaddlePoints;
  values: TArray<TArray<integer>>;
  expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, rows, columns);
  values[0,0] := 3; values[0,1] := 1; values[0,2] := 3;
  values[1,0] := 3; values[1,1] := 2; values[1,2] := 4;

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 2);
  expected[0] := TTuple<integer,integer>.Create(0,0);
  expected[1] := TTuple<integer,integer>.Create(0,2);
  Assert.AreEqual(expected, SaddlePoints.Calculate);
end;

procedure TSaddlePointTests.Can_identify_saddle_point_in_bottom_right_corner;
const
  rows = 3;
  columns = 3;
var
  SaddlePoints: ISaddlePoints;
  values: TArray<TArray<integer>>;
  expected: TArray<TTuple<integer,integer>>;
begin
  SetLength(values, rows, columns);
  values[0,0] := 8; values[0,1] := 7; values[0,2] := 9;
  values[1,0] := 6; values[1,1] := 7; values[1,2] := 6;
  values[2,0] := 3; values[2,1] := 2; values[2,2] := 5;

  SaddlePoints := newSaddlePoints(values);

  SetLength(expected, 1);
  expected[0] := TTuple<integer,integer>.Create(2,2);
  Assert.AreEqual(expected, SaddlePoints.Calculate);
end;

initialization
  TDUnitX.RegisterTestFixture(TSaddlePointTests);
end.
unit uSaddlePoints;

interface

uses uSaddlePointsTests;

type
  ISaddlePoints = interface
    function Calculate : TArray<TTuple<integer,integer>>;
  end;

  function newSaddlePoints(values: TArray<TArray<integer>>) : ISaddlePoints;

implementation

uses System.Generics.Collections, System.SysUtils;

type

  TSaddlePoint = class(TInterfacedObject, ISaddlePoints)
  private

  type
    TRow = TArray<integer>;
    TMatrix = TArray<TRow>;
    TLocTuple = TTuple<integer, integer>;
    TTupleList = TList<TLocTuple>;

  var
    FValues : TMatrix;
    FRowMaxes : TTupleList;
    procedure FFindMaxes(ARow : TRow; ArowInd : integer);
    function FIsMin(AEl : TLocTuple) : boolean;
    function FFindSaddles : TArray<TLocTuple>;
  public
    constructor Create(values: TMatrix);
    destructor Destroy; override;
    function Calculate : TArray<TlocTuple>;
  end;

function newSaddlePoints(values: TArray<TArray<integer>>) : ISaddlePoints;
begin
  Result := TSaddlePoint.Create(values);
end;

{ TsaddlePoint }

function TSaddlePoint.Calculate: TArray<TLocTuple>;
var i : integer;
begin
  for I := low(FValues) to High(FValues) do
    FFindMaxes(FValues[i], i);
  result := FFindSaddles;
end;

constructor TSaddlePoint.Create(values: TMatrix);
begin
  inherited Create;
  FValues := values;
  FRowMaxes := TTupleList.Create;
end;

destructor TSaddlePoint.Destroy;
begin
  FRowMaxes.DisposeOf;
  inherited;
end;

procedure TSaddlePoint.FFindMaxes(ARow : TRow; ArowInd : integer);
var
  I, Max: Integer;
  MaxList : TTupleList;
begin
  Max := low(integer);
  MaxList :=  TTupleList.Create;
  try
    for I := Low(ARow) to High(ARow) do
      if ARow[i] >= Max then
      begin
        if ARow[i] > Max then
        begin
          MaxList.Clear;
          Max := ARow[i];
        end;
        MaxList.Add(TLocTuple.Create(ArowInd,I));
      end;
    FRowMaxes.AddRange(MaxList.ToArray);
  finally
    MaxList.DisposeOf;
  end;
end;

function TSaddlePoint.FIsMin(AEl : TLocTuple) : boolean;
var I: Integer;
begin
  Result := true;
  for I := low(FValues) to High(FValues) do
    if FValues[i, AEl.Value2] < FValues[AEl.Value1, AEl.Value2] then
      exit(false);
end;

function TSaddlePoint.FFindSaddles : TArray<TLocTuple>;
var
  I: Integer;
begin
  for i := FRowMaxes.Count - 1 downto 0 do
    if not FIsMin(FRowMaxes.Items[i]) then
      FRowMaxes.Delete(i);
  Result := FRowMaxes.ToArray;
end;

end.

Community comments

Find this solution interesting? Ask the author a question to learn more.

What can you learn from this solution?

A huge amount can be learned from reading other peopleโ€™s code. This is why we wanted to give exercism users the option of making their solutions public.

Here are some questions to help you reflect on this solution and learn the most from it.

  • What compromises have been made?
  • Are there new concepts here that you could read more about to improve your understanding?