Exercism v3 launches on Sept 1st 2021. Learn more! 🚀🚀🚀
Avatar of Neftali

Neftali's solution

to Collatz Conjecture in the Delphi Pascal Track

Published at Jan 15 2020 · 2 comments
Instructions
Test suite
Solution

The Collatz Conjecture or 3x+1 problem can be summarized as follows:

Take any positive integer n. If n is even, divide n by 2 to get n / 2. If n is odd, multiply n by 3 and add 1 to get 3n + 1. Repeat the process indefinitely. The conjecture states that no matter which number you start with, you will always reach 1 eventually.

Given a number n, return the number of steps required to reach 1.

Examples

Starting with n = 12, the steps would be as follows:

  1. 12
  2. 6
  3. 3
  4. 10
  5. 5
  6. 16
  7. 8
  8. 4
  9. 2
  10. 1

Resulting in 9 steps. So for input n = 12, the return value would be 9.

Testing

In order to run the tests for this track, you will need to install DUnitX. Please see the installation instructions for more information.

Loading Exercises into Delphi

If Delphi is properly installed, and *.dpr file types have been associated with Delphi, then double clicking the supplied *.dpr file will start Delphi and load the exercise/project. control + F9 is the keyboard shortcut to compile the project or pressing F9 will compile and run the project.

Alternatively you may opt to start Delphi and load your project via. the File drop down menu.

When Questions Come Up

We monitor the Pascal-Delphi support room on gitter.im to help you with any questions that might arise.

Submitting Exercises

Note that, when trying to submit an exercise, make sure the exercise file you're submitting is in the exercism/delphi/<exerciseName> directory.

For example, if you're submitting ubob.pas for the Bob exercise, the submit command would be something like exercism submit <path_to_exercism_dir>/delphi/bob/ubob.pas.

Source

An unsolved problem in mathematics named after mathematician Lothar Collatz https://en.wikipedia.org/wiki/3x_%2B_1_problem

Submitting Incomplete Solutions

It's possible to submit an incomplete solution so you may request help from a mentor.

uCollatzconjectureTests.pas

unit uCollatzconjectureTests;

interface
uses
  DUnitX.TestFramework;

const
  CanonicalVersion = '1.2.0.1';

type
  [TestFixture]
  CollatzconjectureTest = class(TObject)
  public
    [Testcase('Zero steps for one', '1, 0')]
//    [Ignore('Comment the "[Ignore]" statement to run the test')]
    procedure Zero_steps_for_one(const aNumber: integer; const aExpected: integer);

    [Testcase('Divide if even','16, 4')]
    [Ignore]
    procedure Divide_if_even(const aNumber: integer; const aExpected: integer);

    [Testcase('Even and odd steps','12, 9')]
    [Ignore]
    procedure Even_and_odd_steps(const aNumber: integer; const aExpected: integer);

    [Testcase('Large number of even and odd steps', '1000000, 152')]
    [Ignore]
    procedure Large_number_of_even_and_odd_steps(const aNumber: integer; const aExpected: integer);

    [Testcase('Zero is an error', '0,error: Only positive numbers are allowed')]
    [Ignore]
    procedure Zero_is_an_error(const aNumber: integer; const aExpected: string);

    [Testcase('Negative value is an error', '-15,error: Only positive numbers are allowed')]
    [Ignore]
    procedure Negative_value_is_an_error(const aNumber: integer; const aExpected: string);
  end;

implementation
uses uCollatzconjecture;

procedure CollatzconjectureTest.Zero_steps_for_one(const aNumber: integer; const aExpected: integer);
begin
  Assert.AreEqual(aExpected, collatzSteps(aNumber));
end;

procedure CollatzconjectureTest.Divide_if_even(const aNumber: integer; const aExpected: integer);
begin
  Assert.AreEqual(aExpected, collatzSteps(aNumber));
end;

procedure CollatzconjectureTest.Even_and_odd_steps(const aNumber: integer; const aExpected: integer);
begin
  Assert.AreEqual(aExpected, collatzSteps(aNumber));
end;

procedure CollatzconjectureTest.Large_number_of_even_and_odd_steps(const aNumber: integer; const aExpected: integer);
begin
  Assert.AreEqual(aExpected, collatzSteps(aNumber));
end;

procedure CollatzconjectureTest.Zero_is_an_error(const aNumber: integer; const aExpected: string);
var MyProc: TTestLocalMethod;
begin
  MyProc := procedure
            begin
              collatzSteps(aNumber);
            end;

  Assert.WillRaiseWithMessage(MyProc, EIllegalNumber, aExpected);
end;

procedure CollatzconjectureTest.Negative_value_is_an_error(const aNumber: integer; const aExpected: string);
var MyProc: TTestLocalMethod;
begin
  MyProc := procedure
            begin
              collatzSteps(aNumber);
            end;

  Assert.WillRaiseWithMessage(MyProc, EIllegalNumber, aExpected);
end;

initialization
  TDUnitX.RegisterTestFixture(CollatzconjectureTest);
end.
unit uCollatzconjecture;

interface

uses
  System.Sysutils;

type
  EIllegalNumber = class(Exception);

function collatzSteps(AValue:integer):Integer;

implementation

// SOLUTION: Recursive call
function collatzSteps(AValue:integer):Integer;
begin
  // Numbers <= 0 not allowed
  if (AValue <= 0) then
    raise EIllegalNumber.Create('error: Only positive numbers are allowed');

  // for 1 => 0 steps
  if (AValue = 1) then begin
    Result := 0;
    Exit;
  end;

  // Others numbers (use recursive call) and increment the number of steps returned
  if Odd(AValue) then
    Result := collatzSteps((Avalue * 3) + 1) + 1
  else
    Result := collatzSteps(AValue div 2) + 1;
end;

end.

Community comments

Find this solution interesting? Ask the author a question to learn more.
Avatar of rpottsoh

This is very clean solution. How could it guard against potential stack overflow issues if there are too many steps to get AValuedown to 1?

Avatar of Neftali

Hi Ray. For too large numbers I (many steps) think the solution using WHILE would be better.

Neftali's Reflection

Using a WHILE structure